updated ebuild

clapack-3.2.1-r1.ebuild (text/plain), 1.75 KB, created by Andreas K. Hüttel on 2010-03-15 23:05:29 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/clapack/clapack-3.2.1.ebuild,v 1.1 2010/03/04 09:57:23 jlec Exp $

EAPI="3"

inherit eutils multilib toolchain-funcs

DESCRIPTION="f2c'ed version of LAPACK"
HOMEPAGE="http://www.netlib.org/clapack/"
SRC_URI="http://www.netlib.org/${PN}/${P}.tgz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="static"

RDEPEND=">=dev-libs/libf2c-20081126[static?]"
DEPEND="${RDEPEND}"
S="${WORKDIR}"/CLAPACK-${PV}

src_prepare() {
	rm -rf F2CLIBS BLAS

	epatch "${FILESDIR}/${P}-so.patch"

	sed \
		-e "s:^CC.*$:CC = $(tc-getCC):g" \
		-e "s:^CFLAGS.*$:CFLAGS = ${CFLAGS} -DNO_BLAS_WRAP -fPIC:g" \
		-e "s:^LOADER.*$:LOADER = $(tc-getCC):g" \
		-e "s:^ARCHSO.*$:ARCHSO = $(tc-getCC) -shared:g" \
		-e "s:^LOADOPTS.*$:LOADOPTS = ${LDFLAGS}:g" \
		-e "s:^NOOPT.*$:NOOPT = -fPIC:g" \
		-e "s:^SOFLAGS.*$:SOFLAGS = ${LDFLAGS} -lblas -lpthread -lf2c:g" \
		-e "s:^F2CLIB.*$:F2CLIB = -lf2c:g" \
		-e "s:^BLASLIB.*$:BLASLIB = -lblas:g" \
		-e "s:LAPACKLIB.*$:LAPACKLIB = libclapack.a:g" \
		-e "s:LAPACKSOLIB.*$:LAPACKSOLIB = libclapack.so:g" \
		make.inc.example > make.inc

	sed \
		-e 's:"f2c.h":<f2c.h>:g' \
		-i SRC/*.c || die
}

src_compile() {
	emake -C INSTALL || die "compile failed"
	emake -C SRC     || die "compile failed"
}

src_test() {
	emake -C TESTING/MATGEN || die "test matrix generator build failed"
	emake -C TESTING/EIG || die "eigenvalue test build failed"
	emake -C TESTING/LIN || die "linear algebra test build failed"
	MAKEOPTS="-j1" emake -C TESTING || die "testing failed"
}

src_install() {
	insinto /usr/include
	doins INCLUDE/${PN}.h || die
	if use static; then 
		dolib.a lib${PN}.a || die
	fi
	dolib.so lib${PN}.so || die
}