# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/scm/scm-5.5.5-r1.ebuild,v 1.1 2009/02/03 16:34:28 hkbst Exp $

inherit versionator eutils

#version magic thanks to masterdriverz and UberLord using bash array instead of tr
trarr="0abcdefghi"
MY_PV="$(get_version_component_range 1)${trarr:$(get_version_component_range 2):1}$(get_version_component_range 3)"
MY_P=${PN}-${MY_PV}

DESCRIPTION="Scheme implementation from author of slib"
HOMEPAGE="http://swiss.csail.mit.edu/~jaffer/SCM"
SRC_URI="http://swiss.csail.mit.edu/ftpdir/scm/${MY_P}.zip"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

#unzip for unpacking
RDEPEND=""
DEPEND="app-arch/unzip
		>=dev-scheme/slib-3.1.5"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i -e 's#local/##' \
		-e 's:man1dir = $(prefix)man/man1/:man1dir = $(prefix)share/man/man1/:' \
		-e '/strip .*/d' \
		Makefile || die
}

src_compile() {
	#parallel make fails sometimes
	emake -j1 scmlit || die
	echo "srcdir=/usr/share/scm/" > srcdir.mk
	./build --compiler-options="${CFLAGS}" --linker-options="${LDFLAGS}" -F macro -F inexact &> _compile.sh || die
	sh _compile.sh || die
}

src_install() {
	emake DESTDIR="${D}" install || die
}

pkg_postinst() {
	[ "${ROOT}" == "/" ] && pkg_config
}

pkg_config() {
	einfo "Regenerating catalog..."
	scm -e "(require 'new-catalog)"
}