Ebuild with .desktop & mime

adobe-air-sdk-bin-1.5.3.ebuild (text/plain), 1.38 KB, created by Michał Górny on 2010-03-07 22:36:25 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils fdo-mime

DESCRIPTION="Adobe AIR SDK"
HOMEPAGE="http://www.adobe.com/products/air/tools/sdk/"
SRC_URI="http://airdownload.adobe.com/air/lin/download/${PV}/AdobeAIRSDK.tbz2 -> AdobeAIRSDK-${PV}.tbz2"

LICENSE="AdobeAirSDK"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

DEPEND="amd64? ( net-libs/xulrunner-bin
	app-emulation/emul-linux-x86-baselibs
	app-emulation/emul-linux-x86-gtklibs )"
RDEPEND="${RDEPEND}
	app-arch/unzip"

QA_PRESTRIPPED=".*\.so
	/opt/Adobe/AirSDK/bin/adl"
QA_EXECSTACK="*/libCore.so"

src_install() {
	sdkdir=opt/Adobe/AirSDK
	rtdir='runtimes/air/linux/Adobe AIR/Versions/1.0'

	# drop broken symlinks
	rm -r "${rtdir}"/Resources/nss3/[01]d || die

	insinto /${sdkdir}
	doins -r * || die

	cd "${D}" || die
	fperms 0755 ${sdkdir}/bin/* ${sdkdir}/"${rtdir}"/{libCore.so,Resources/{nss3/None/*.so,lib*.so*}} || die

	exeinto /opt/bin
	doexe "${FILESDIR}"/airstart || die

	# install the file association
	# (we can't use make_desktop_entry because we like to have NoDisplay)
	domenu "${FILESDIR}"/airstart.desktop || die

	insinto /usr/share/mime/packages
	doins "${FILESDIR}"/${PN}.xml || die
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}