games-util/nforenum

nforenum-0_pre2309.ebuild (text/plain), 1.00 KB, created by Piotr Szymaniak on 2010-03-07 19:59:40 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit games

MY_PV=${PV/0_pre/r}

DESCRIPTION="NFORenum is a tool checking NFO code for errors."
HOMEPAGE="http://binaries.openttd.org/extra/nforenum/"
SRC_URI="http://binaries.openttd.org/extra/${PN}/${MY_PV}/${PN}-${MY_PV}-source.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="dev-libs/boost"

S=${WORKDIR}/${PN}-${MY_PV}

src_prepare() {
	cat > Makefile.local <<-__EOF__
		CC = $(tc-getCXX)
		CXX = $(tc-getCXX)
		CFLAGS = ${CFLAGS}
		CXXFLAGS = ${CXXFLAGS}
		LDOPTS = ${LDFLAGS}
		STRIP = :
	__EOF__

	sed -e '/^CFLAGS = /{s:-g::; s:-O[13]::g; s:\$(CFLAGAPP)::; s:=:+=:; p; s:CFLAGS:CXXFLAGS:}' \
		-e '/^CFLAGS += /{p; s:CFLAGS:CXXFLAGS:}' \
		-e '/^CXXFLAGS = /d' \
		-i Makefile || die "sed failed on Makefile"
}

src_compile() {
	emake V=1 || die "emake failed"
}

src_install() {
	dobin renum || die "dobin failed"
	dodoc doc/*.en.txt || die "dodoc failed"
}