# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dahdi/dahdi-2.2.0.2.ebuild,v 1.1 2009/10/22 18:19:35 chainsaw Exp $

inherit linux-mod eutils flag-o-matic

MY_P="${P/dahdi/dahdi-linux}"
MY_S="${WORKDIR}/${MY_P}"

DESCRIPTION="Kernel modules for Digium compatible hardware (formerly known as Zaptel)."
HOMEPAGE="http://www.asterisk.org"
SRC_URI="http://downloads.digium.com/pub/telephony/dahdi-linux/releases/${MY_P}.tar.gz
http://downloads.digium.com/pub/telephony/firmware/releases/dahdi-fwload-vpmadt032-1.17.0.tar.gz
http://downloads.digium.com/pub/telephony/firmware/releases/dahdi-fw-oct6114-064-1.05.01.tar.gz
http://downloads.digium.com/pub/telephony/firmware/releases/dahdi-fw-oct6114-128-1.05.01.tar.gz
http://downloads.digium.com/pub/telephony/firmware/releases/dahdi-fw-tc400m-MR6.12.tar.gz
http://downloads.digium.com/pub/telephony/firmware/releases/dahdi-fw-vpmadt032-1.07.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ecoslec"

DEPEND=""
RDEPEND=""

src_unpack() {
	unpack ${A}

	# Fix udev rules to work with both asterisk and callweaver
	sed -i 's/GROUP="asterisk"/GROUP="dialout"/' "${MY_S}"/build_tools/genudevrules

	# Copy the firmware tarballs over, the makefile will try and download them otherwise
	for file in ${A} ; do
		cp "${DISTDIR}"/${file} "${MY_P}"/drivers/dahdi/firmware/
	done
	# But without the .bin's it'll still fall over and die, so copy those too.
	cp *.bin "${MY_P}"/drivers/dahdi/firmware/

	epatch "${FILESDIR}"/${P}-no-depmod.patch

	# GCC 4.4 compatibility, the quick 'n dirty way
	# error: dereferencing pointer to incomplete type
	epatch "${FILESDIR}"/${P}-gcc44-hack.patch

	# enable CONFIG_DAHDI_CORE_TIMER <https://issues.asterisk.org/view.php?id=15736>
	epatch "${FILESDIR}"/${P}-core-timer.patch

	# enable oslec (ripped from kernel 2.6.32)
	epatch "${FILESDIR}"/${P}-oslec.patch

	# vzaphfc (2010-01-10) <http://code.google.com/p/zaphfc/>
	epatch "${FILESDIR}"/dahdi-tzafrir-branch-20100110.patch
	# vzaphfc (2010-02-10) <http://code.google.com/p/zaphfc/> - isn't working for me (cause 34) (ojaksch@com-in.de)
#	epatch "${FILESDIR}"/dahdi-tzafrir-branch-20100210.patch

	# and finally enable the whole stuff
	epatch "${FILESDIR}"/${P}-kbuild-driver.patch
}

src_compile() {
	cd "${MY_P}"
	unset ARCH
	emake KSRC="${KERNEL_DIR}" DESTDIR="${D}" all || die "Compilation failed"
}

src_install() {
	cd "${MY_P}"

	# setup directory structure so udev rules get installed
	mkdir -p "${D}"/etc/udev/rules.d

	einfo "Installing kernel module"
	emake KSRC="${KERNEL_DIR}" DESTDIR="${D}" install || die "Installation failed"
	rm -rf "$D"/lib/modules/*/modules.*
}

pkg_postinst() {
	depmod || die "depmod failed" 
	if use ecoslec && linux-info_get_any_version && linux_config_src_exists; then
		CONFIG_CHECK="~ECHO"
		local ERROR_ECHO="You need CONFIG_ECHO enabled in your kernel sources in order to use oslec support."
		check_extra_config
	fi
}