# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.02.ebuild,v 1.3 2009/03/02 09:49:03 dev-zero Exp $

EAPI="2"

inherit multilib python subversion autotools

ESVN_REPO_URI="https://fsckyou.info/svn/blueman/trunk"

DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks."
HOMEPAGE="http://blueman-project.org/"
#SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="gnome network nls obex"

CDEPEND="dev-libs/glib:2
	>=x11-libs/gtk+-2.12:2
	x11-libs/startup-notification
	>=dev-lang/python-2.5
	dev-python/pygobject
	dev-python/dbus-python
	dev-python/notify-python
	dev-python/pygtk
	net-wireless/bluez
	dev-python/pybluez"

DEPEND="${CDEPEND}
	nls? ( dev-util/intltool sys-devel/gettext )
	dev-util/pkgconfig"
#	>=dev-python/pyrex-0.9.8"

RDEPEND="${CDEPEND}
	network? ( || ( net-dns/dnsmasq =net-misc/dhcp-3* ) )
	gnome? ( dev-python/gconf-python )
	obex? ( >=app-mobilephone/obex-data-server-0.4.4 )
	gnome-extra/policykit-gnome"
#	sys-apps/dbus"

src_unpack() {
	subversion_src_unpack
	./autogen.sh || die "./autogen.sh failed"
}


src_prepare() {
	# disable pyc compiling
	ln -s $(type -P true) py-compile
}

src_configure() {
	econf $(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README

	if ! use gnome ; then
		python_version
		rm "${D}/usr/$(get_libdir)/python${PYVER}/site-packages/blueman/plugins/config/Gconf.py"
	fi
}

pkg_postinst() {
	python_version
	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/blueman
	python_need_rebuild
}

pkg_postrm() {
	python_mod_cleanup
}