elfkickers-2.0a-r4.ebuild (Corrected ebuild)

elfkickers-2.0a-r4.ebuild (text/plain), 1.57 KB, created by Christophe LEFEBVRE on 2010-03-01 19:23:10 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/elfkickers/elfkickers-2.0a-r4.ebuild,v 1.9 2009/03/04 17:08:31 drizzt Exp $

EAPI="2"

inherit eutils multilib toolchain-funcs

MY_PN=${PN/elf/ELF}
S=${WORKDIR}/${MY_PN}

DESCRIPTION="collection of programs to manipulate ELF files: sstrip, rebind, elfls, elftoc"
HOMEPAGE="http://www.muppetlabs.com/~breadbox/software/elfkickers.html"
SRC_URI="http://www.muppetlabs.com/~breadbox/pub/software/${MY_PN}-${PV}.tar.gz
	mirror://gentoo/elfkickers-2.0a-r2.patch.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm hppa ~mips ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="doc"

DEPEND="app-misc/pax-utils"
RDEPEND=""

src_prepare() {
	epatch "${WORKDIR}"/elfkickers-2.0a-r2.patch

	sed -i -e '/^SUBDIRS/s:tiny::' Makefile
	use x86 || sed -i -e '/^SUBDIRS/s:ebfc::' Makefile
	use x86 && sed -i -e 's:linux/elf.h:elf.h:' ebfc/*.c
	(cd tiny && make clean)
}

src_compile() {
	for bits in 32 64; do
		emake CC=$(tc-getCC) CFLAGS="-DELF_CLASS=ELFCLASS${bits} ${CFLAGS}" clean all
		for x in elfls elftoc rebind sstrip; do
			mv ${x}/$x{,${bits}} || die "moving failed of ${x}{,${bits}"
		done
	done
}

src_install() {
	for d in elfls elftoc rebind sstrip ; do
		newdoc ${d}/README README.${d}
		dobin ${d}/${d}{32,64} || die "dobin ${d}{32,64} failed"
		if [ -f $d/*.1 ]; then
			doman $d/*.1 || die
		fi
		case $(get_libdir) in
			lib64) dosym /usr/bin/${d}64 /usr/bin/${d};;
			lib|lib32) dosym /usr/bin/${d}32 /usr/bin/${d};;
		esac
	done
	dodoc Changelog README || die
}