ezbounce-1.99.14.ebuild (Corrected ebuild)

ezbounce-1.99.14.ebuild (text/plain), 1.07 KB, created by Christophe LEFEBVRE on 2010-03-01 19:11:56 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/ezbounce/ezbounce-1.99.14.ebuild,v 1.3 2009/06/02 12:53:35 flameeyes Exp $

EAPI="2"

inherit eutils

DESCRIPTION="a small IRC bouncer"
HOMEPAGE="http://www.linuxftw.com/ezbounce/"
SRC_URI="http://www.linuxftw.com/${PN}/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="boost doc ssl"
RESTRICT="test"

DEPEND="net-misc/mdidentd
	ssl? ( dev-libs/openssl )
	boost? ( dev-libs/boost )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-build.patch #251445
	epatch "${FILESDIR}"/${P}-asneeded.patch
	epatch "${FILESDIR}"/${P}+glibc-2.10.patch
}

src_configure(){
	econf \
		$(use_with ssl) \
		$(use_with boost) \
		|| die
}

src_compile() {
	emake CXX_OPTIMIZATIONS="${CXXFLAGS}" || die
}

src_install() {
	dobin ezbounce || die
	dosym ezbounce /usr/bin/ezb
	doman docs/ezbounce.1 || die
	dodoc CHANGES TODO README ezb.conf sample.* || die
	if use doc; then
	  docinto docs
	  dodoc docs/{*.txt,FAQ,REPORTING-BUGS} || die
	fi
}