net-dialup/martian-modem/martian-modem-20080625.ebuild

martian-modem-20080625.ebuild (text/plain), 1.85 KB, created by Doktor Notor on 2010-02-27 10:17:00 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit linux-mod eutils

MY_P="${PN}_${PV}.orig"
DESCRIPTION="Winmodems with Lucent Apollo (ISA) and Mars (PCI) chipsets"
HOMEPAGE="http://linmodems.technion.ac.il/"
SRC_URI="http://ftp.de.debian.org/debian/pool/non-free/m/martian-modem/${MY_P}.tar.gz"

LICENSE="GPL-2 AgereSystems-WinModem"
KEYWORDS="-* ~x86"
IUSE=""

DEPEND="!net-dialup/ltmodem"
RDEPEND="${DEPEND}"

# Do NOT remove this. Stripping results in broken communication
# with core state communication channel (also see QA_* stuff below)
RESTRICT="strip"

# contains proprietary precompiled 32 bit ltmdmobj.o
QA_EXECSTACK_x86="usr/sbin/martian_modem"
QA_WX_LOAD_x86="usr/sbin/martian_modem"

S="${WORKDIR}/${P/modem/full}"
MODULE_NAMES="martian_dev(ltmodem::kmodule)"
CONFIG_CHECK="SERIAL_8250"
SERIAL_8250_ERROR="This driver requires you to compile your kernel with serial core (CONFIG_SERIAL_8250) support."

pkg_setup() {
	linux-mod_pkg_setup

	if kernel_is 2 4; then
		eerror "This driver works only with 2.6 kernels!"
		die "unsupported kernel detected"
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${P}-include_2.6.32-scheduler.patch"
	BUILD_TARGETS="all"
	BUILD_PARAMS="KERNEL_DIR='${KV_DIR}' SUBLEVEL='${KV_PATCH}'"
}

src_install() {
	linux-mod_src_install
	
	# userspace daemon and initscripts stuff
	dosbin modem/martian_modem
	newconfd "${FILESDIR}/${PN}.conf.d" ${PN}
	newinitd "${FILESDIR}/${PN}.init.d" ${PN}
}

pkg_postinst() {
	linux-mod_pkg_postinst

	if linux_chkconfig_present SMP ; then
		elog "You have SMP (symmetric multi processor) support enabled in kernel."
		elog "You should run martian_modem with --smp option enabled."
	fi
	elog "See /etc/conf.d/${PN} for other configuration options"
	elog
	elog "If using net-dialup/wvdial, you need \"Carrier Check = no\" line."
}