Updated ebuild from an apparently maintained git clone

acx-mac80211-20091231.ebuild (text/plain), 1.01 KB, created by Malte Starostik on 2010-02-20 17:13:19 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit git linux-mod

DESCRIPTION="Driver for the ACX100 and ACX111 wireless chipset (CardBus, PCI, USB)"
HOMEPAGE="http://acx100.sourceforge.net/"

EGIT_REPO_URI="git://gitorious.org/~oli1417/acx-mac80211/oli1417-clone.git"
EGIT_COMMIT="221a4fa972f7c95530b37aa1d397d706ace2127d"

LICENSE="GPL-2 as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE="+pci usb"
RDEPEND="net-wireless/wireless-tools
		net-wireless/acx-firmware"

MODULE_NAMES="acx-mac80211(net:${S})"
CONFIG_CHECK="WIRELESS_EXT FW_LOADER"
unset SRC_URI

pkg_setup() {
	linux-mod_pkg_setup
	BUILD_PARAMS="-C ${KV_DIR} SUBDIRS=${S}"
}

src_unpack() {
	git_src_unpack
}

src_compile() {
	KCONFIG="CONFIG_ACX_MAC80211=m"
	use pci && KCONFIG="${KCONFIG} CONFIG_ACX_MAC80211_PCI=y"
	use usb && KCONFIG="${KCONFIG} CONFIG_ACX_MAC80211_USB=y"
	emake EXTRA_KCONFIG="${KCONFIG}" || die "emake failed"
}

src_install() {
	linux-mod_src_install

	dodoc README
}