# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit versionator games

# Upstream are using N.N.NvN as a versioning system,
# so the archive is renamed from the Gentoo scheme
MAJOR_PV=$(get_version_component_range 1-2)
MY_P=${P/_p/v}
DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
HOMEPAGE="http://rephial.org/"
SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${MY_P}-src.tar.gz"

LICENSE="Moria"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gtk ncurses sdl sound X"

RDEPEND="
	gtk? ( gnome-base/libglade
		   x11-libs/pango
		   x11-libs/gtk+:2
		   dev-libs/glib:2 )
	X? ( x11-libs/libSM
		 x11-libs/libX11 )
	!ncurses? ( !X? ( !sdl? ( !gtk? ( sys-libs/ncurses ) ) ) )
	sdl? ( media-libs/sdl-ttf
		   media-libs/sdl-image )
	sound? ( media-libs/sdl-mixer )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	# Rename the build directory to gentoo scheme
	# if required
	if [ "${MY_P}" != "${P}" ]; then
		mv ${MY_P} ${P}
	fi
}

# If all clients are disabled, ncurses is enabled again
# rather than printing an error and dumping out an emerge
# queue
src_configure() {
	econf \
		--bindir="${GAMES_BINDIR}" \
		--with-configpath="${GAMES_SYSCONFDIR}/${PN}" \
		--with-libpath="${GAMES_DATADIR}/${PN}" \
		--with-varpath="${GAMES_STATEDIR}/${PN}" \
		--with-private-dirs \
		$(use_enable X x11) \
		$(use_enable gtk) \
		$(use_enable sdl) \
		$(use_enable ncurses curses) \
		$( use !gtk && use !sdl && use !ncurses && use !X && \
			echo --enable-curses) \
		$(use_enable sound sdl-mixer)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# Edit files are now system config files in Angband, but
	# users will be hidden from applying updates by default
	echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/edit/\"" \
		> "${T}"/99${PN};
	doenvd "${T}"/99${PN} || die

	dodoc changes.txt faq.txt readme.txt thanks.txt || die

	# Create desktop entries if required.
	ICON_LOC="${GAMES_DATADIR}/${PN}/xtra/icon/att-32.png"
	if use X; then
		make_desktop_entry "angband -mx11" "Angband (X11)" "${ICON_LOC}" || die
	fi

	if use sdl; then
		make_desktop_entry "angband -msdl" "Angband (SDL)" "${ICON_LOC}" || die
	fi

	if use gtk; then
		make_desktop_entry "angband -mgtk" "Angband (GTK)" "${ICON_LOC}" || die
	fi
	prepgamesdirs
}

pkg_postinst() {
	einfo "Angband now uses private savefiles instead of system-wide ones"
	einfo "This version of Angband is not compatible with the save files"
	einfo "of previous versions"
	games_pkg_postinst
}