bogofilter-0.15.10.ebuild

bogofilter-0.15.10.ebuild (text/plain), 2.01 KB, created by Torsten Veller (RETIRED) on 2003-12-09 02:56:29 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header:

IUSE="doc tdb"

DESCRIPTION="Bayesian spam filter designed with fast algorithms, and tuned for speed."
HOMEPAGE="http://bogofilter.sourceforge.net/"
SRC_URI="mirror://sourceforge/bogofilter/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

DEPEND="virtual/glibc
	doc? ( app-text/xmlto )
	tdb? ( dev-libs/tdb ) : ( >=sys-libs/db-3 )"

RDEPEND="virtual/glibc
	tdb? ( dev-libs/tdb ) : ( >=sys-libs/db-3 )"

src_compile() {
	local myconf
	myconf=""
	use tdb && myconf="${myconf} --with-database=tdb"

	econf \
		${myconf} || die

	emake || die "compile problem"
}

src_install() {
	make install DESTDIR=${D} || die

	exeinto /usr/lib/${PN}/contrib
	doexe contrib/bogofilter-qfe contrib/bogogrep contrib/mime.get.rfc822 
	doexe contrib/parmtest.sh contrib/randomtrain contrib/scramble
	doexe contrib/*.pl

	insinto /usr/lib/${PN}/contrib
	doins contrib/README.randomtrain contrib/bogo.R 
	doins contrib/dot-qmail-bogofilter-default contrib/trainbogo.sh

	dodoc AUTHORS CHANGES* COPYING INSTALL METHODS NEWS README 
	dodoc RELEASE.NOTES* TODO UPGRADE
	dodoc doc/integrating-with-* doc/*.HOWTO doc/README.tdb
	dodoc contrib/*.example

	dodir /usr/share/doc/${P}/samples
	mv ${D}/etc/* ${D}/usr/share/doc/${PF}/samples/
	rmdir ${D}/etc

	if use doc; then  
		dohtml doc/*.html
	else
		dohtml doc/bogofilter-faq.html
	fi
}

pkg_postinst() {
	einfo ""
	einfo "For best results it is recommended to retrain bogofilter"
	einfo "if you upgrade from a version 0.15.4 or older,"
	einfo "because the header handling was improved."
	einfo ""
	einfo "With version 0.14 the options of bogofilter have changed."
	einfo "If you update from an older version, you eventually must change"
	einfo "your configuration."
	einfo ""
	einfo "Read bogofilter's manual 'man bogofilter' and have a look at"
	einfo "the examples in the doc directory for tips on how"
	einfo "to integrate bogofilter with procmail, maildrop, postfix or qmail."
	einfo ""
}