the ebuild

nginx-0.7.65.ebuild (text/plain), 3.51 KB, created by Chris Beswick on 2010-02-02 12:05:12 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils ssl-cert perl-module

DESCRIPTION="Robust, small and high performance http and reverse proxy server"
HOMEPAGE="http://nginx.net/"
SRC_URI="http://sysoev.ru/nginx/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug ipv6 +pcre perl ssl +zlib"

MODULES_STD="charset gzip ssi userid access auth_basic autoindex geo map referer rewrite proxy fastcgi memcached limit_zone limit_req empty_gif browser upstream_ip_hash"
MODULES_OPT="realip addition xslt image_filter geoip sub dav flv gzip_static random_index secure_link stub_status"
MODULES_MAIL="imap pop3 smtp"

for module in ${MODULES_STD}; do
	IUSE="${IUSE} +nginx_modules_${module}"
done

for module in ${MODULES_OPT}; do
	IUSE="${IUSE} nginx_modules_${module}"
done

for module in ${MODULES_MAIL}; do
	IUSE="${IUSE} nginx_modules_${module}"
done

DEPEND="ssl? ( dev-libs/openssl )
	pcre? ( >=dev-libs/libpcre-4.2 )
	zlib? ( sys-libs/zlib )
	perl? ( >=dev-lang/perl-5.8 )"
RDEPEND="${DEPEND}"

pkg_setup() {
	ebegin "Creating nginx user and group"
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
	eend ${?}
}

src_unpack() {
	unpack ${A}
	sed -i 's/ make/ \\$(MAKE)/' "${S}"/auto/lib/perl/make || die
}

src_configure() {
	local myconf

	use debug	&& myconf="${myconf} --with-debug"
	use ipv6	&& myconf="${myconf} --with-ipv6"
	use pcre	|| myconf="${myconf} --without-pcre"
	use pcre	&& myconf="${myconf} --with-pcre"
	use perl	&& myconf="${myconf} --with-http_perl_module"
	use ssl		&& myconf="${myconf} --with-http_ssl_module"

	use nginx_modules_gzip && ! use zlib && die "nginx gzip module requires zlib"
	use nginx_modules_rewrite && ! use pcre && die "nginx rewrite module requires pcre"

	for module in ${MODULES_STD} ; do
		use "nginx_modules_${module}" || \
			myconf="${myconf} --without-http_${module}_module"
	done

	for module in ${MODULES_OPT} ; do
		use "nginx_modules_${module}" && \
			myconf="${myconf} --with-http_${module}_module"
	done

	for module in ${MODULES_MAIL} ; do
		use "nginx_modules_${module}" || \
			myconf="${myconf} --without-mail_${module}_module"
	done

	if use nginx_modules_smtp || use nginx_modules_pop || use nginx_modules_imap; then
		myconf="${myconf} --with-mail"
		use ssl && myconf="${myconf} --with-mail_ssl_module"
	fi

	./configure \
		--prefix=/usr \
		--with-cc-opt="-I${ROOT}/usr/include" \
		--with-ld-opt="-L${ROOT}/usr/lib" \
		--conf-path=/etc/${PN}/${PN}.conf \
		--http-log-path=/var/log/${PN}/access_log \
		--error-log-path=/var/log/${PN}/error_log \
		--pid-path=/var/run/${PN}.pid \
		--http-client-body-temp-path=/var/tmp/${PN}/client \
		--http-proxy-temp-path=/var/tmp/${PN}/proxy \
		--http-fastcgi-temp-path=/var/tmp/${PN}/fastcgi \
		${myconf} || die "configure failed"
}

src_install() {
	keepdir /var/log/${PN} /var/tmp/${PN}/{client,proxy,fastcgi}

	dosbin objs/nginx
	newinitd "${FILESDIR}"/nginx.init-r2 nginx || die

	cp "${FILESDIR}"/nginx.conf-r4 conf/nginx.conf

	dodir /etc/${PN}
	insinto /etc/${PN}
	doins conf/*

	dodoc CHANGES{,.ru} README

	# logrotate
	insinto /etc/logrotate.d
	newins "${FILESDIR}"/nginx.logrotate nginx || die

	use perl && {
		cd "${S}"/objs/src/http/modules/perl/
		einstall DESTDIR="${D}" INSTALLDIRS=vendor || die "failed to install perl stuff"
		fixlocalpod
	}
}

pkg_postinst() {
	use ssl && {
		if [ ! -f "${ROOT}"/etc/ssl/${PN}/${PN}.key ]; then
			install_cert /etc/ssl/${PN}/${PN}
			chown ${PN}:${PN} "${ROOT}"/etc/ssl/${PN}/${PN}.{crt,csr,key,pem}
		fi
	}
}