Ebuild for angband 3.1.2

angband-3.1.2.ebuild (text/plain), 1.56 KB, created by Stephen Bridges on 2010-01-26 20:10:14 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit flag-o-matic games

DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R.Tolkien"
HOMEPAGE="http://rephial.org/"

SRC_URI="http://rephial.org/downloads/3.1/${P}-src.tar.gz"

LICENSE="Moria"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gtk ncurses sdl sound X"

DEPEND="
	gtk? ( >=gnome-base/libglade-2.0
		   x11-libs/pango
		   >=x11-libs/gtk+-2.0
		   >=dev-libs/glib-2.0 )
	X? ( x11-libs/libSM
		 x11-libs/libX11 )
	ncurses? ( >=sys-libs/ncurses-5 )
	sdl? ( media-libs/sdl-ttf
		   media-libs/sdl-image )
	sound? ( media-libs/sdl-mixer )"

RDEPEND="${DEPEND}"

src_configure() {

	append-ldflags -Wl,-z,now

	econf \
		--bindir="${GAMES_BINDIR}" \
		--with-configpath="${GAMES_SYSCONFDIR}/${PN}/" \
		--with-libpath="${GAMES_DATADIR}/${PN}/" \
		--with-varpath="${GAMES_STATEDIR}/${PN}/" \
		--with-private-dirs \
		$(use_enable X x11) \
		$(use_enable gtk) \
		$(use_enable sdl) \
		$(use_enable ncurses curses) \
		$(use_enable sound sdl-mixer)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/edit/\"" \
		> "${T}"/99${PN};
	doenvd "${T}"/99${PN}

	dodoc changes.txt faq.txt readme.txt thanks.txt || die
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	einfo "Angband now uses private savefiles instead of system-wide ones"
	einfo "This version of Angband is not compatible with the save files"
	einfo "of previous versions"
}