Updated ebuild

reminiscence-0.1.9.ebuild (text/plain), 1.25 KB, created by Vitaly Minko on 2010-01-25 02:04:01 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs games

MY_PN=REminiscence
MY_P=${MY_PN}-${PV}

DESCRIPTION="Reimplementation of the Flashback engine using SDL"
HOMEPAGE="http://cyxdown.free.fr/reminiscence/"
SRC_URI="http://cyxdown.free.fr/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~arm"
IUSE=""

DEPEND="sys-libs/zlib
	media-libs/libsdl[audio,video,joystick]"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch ${FILESDIR}/${PN}-homedir-fix.patch
	epatch ${FILESDIR}/${P}-64bit-fix.patch

	sed -i \
		-e "s:DATA:${GAMES_DATADIR}/${PN}:g" \
		main.cpp \
		|| die "sed failed"
}

src_compile() {
	emake \
		CXX=$(tc-getCXX) \
		CXXFLAGS="${CXXFLAGS} \$(SDL_CFLAGS) \$(DEFINES)" \
		|| die "emake failed"
}

src_install() {
	dodir ${GAMES_DATADIR}/${PN} || die "dodir failed"
	newgamesbin rs reminiscence || die "newgamesbin failed"
	dodoc README TODO
	prepgamesdirs
}

pkg_postinst() { 
	echo
	einfo "To play the game, copy the contents of the PC version's"
	einfo "DATA directory of the original game into ${GAMES_DATADIR}/${PN}."
	einfo "For sound to work you need the Amiga version's .mod files."
	games_pkg_postinst
}