# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

EGIT_REPO_URI="git://git.omp.am/conky.git"
EGIT_BRANCH="master"
#EGIT_TREE="a14cca6592ec506b1a535be43912b4a72b40f11f"

inherit cmake-utils git

DESCRIPTION="An advanced, highly configurable system monitor for X"
HOMEPAGE="http://conky.sourceforge.net/"
SRC_URI=""

LICENSE="GPL-3 BSD LGPL-2.1 MIT"
SLOT="0"
KEYWORDS=""
IUSE="apcupsd audacious curl debug eve hddtemp iconv imlib iostats lua lua-cairo lua-imlib math moc mpd nano-syntax ncurses nvidia +portmon rss thinkpad truetype vim-syntax weather-metar weather-xoap wifi X"

DEPEND_COMMON="
	X? (
		imlib? ( media-libs/imlib2 )
		lua-cairo? ( >=dev-lang/toluapp-1.0.93 x11-libs/cairo[X] )
		lua-imlib? ( >=dev-lang/toluapp-1.0.93 media-libs/imlib2 )
		nvidia? ( media-video/nvidia-settings )
		truetype? ( x11-libs/libXft >=media-libs/freetype-2 )
		x11-libs/libX11
		x11-libs/libXdamage
		x11-libs/libXext
	)
	audacious? ( >=media-sound/audacious-1.5 dev-libs/glib )
	curl? ( net-misc/curl )
	eve? ( net-misc/curl dev-libs/libxml2 )
	portmon? ( dev-libs/glib )
	lua? ( >=dev-lang/lua-5.1 )
	ncurses? ( sys-libs/ncurses )
	rss? ( dev-libs/libxml2 net-misc/curl dev-libs/glib )
	wifi? ( net-wireless/wireless-tools )
	weather-metar? ( net-misc/curl )
	weather-xoap? ( dev-libs/libxml2 net-misc/curl )
	iconv? ( virtual/libiconv )
	>=sys-devel/gcc-4.4
	"
RDEPEND="
	${DEPEND_COMMON}
	apcupsd? ( sys-power/apcupsd )
	hddtemp? ( app-admin/hddtemp )
	moc? ( media-sound/moc )
	nano-syntax? ( app-editors/nano )
	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
	"
DEPEND="
	${DEPEND_COMMON}
	app-text/docbook2X
	"

DOCS="ChangeLog AUTHORS TODO"
HTML_DOCS="doc/docs.html doc/config_settings.html doc/variables.html"

src_configure() {
	local mycmakeargs

	if use X; then
		mycmakeargs="-DBUILD_X11=ON -DOWN_WINDOW=ON -DBUILD_XDAMAGE=ON"
		mycmakeargs="${mycmakeargs} -DBUILD_XDBE=ON -DBUILD_ARGB=ON"
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_build truetype XFT)"
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_build imlib IMLIB2)"
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_build lua-cairo LUA_CAIRO)"
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_build lua-imlib LUA_IMLIB2)"
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_build nvidia)"
	else
		mycmakeargs="-DBUILD_X11=OFF -DBUILD_NVIDIA=OFF"
		mycmakeargs="${mycmakeargs} -DBUILD_LUA_CAIRO=OFF"
		mycmakeargs="${mycmakeargs} -DBUILD_LUA_IMLIB2=OFF"
	fi

	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_build apcupsd)
		$(cmake-utils_use_build audacious)
		$(cmake-utils_use_build curl)
		$(cmake-utils_use_build eve)
		$(cmake-utils_use_build hddtemp)
		$(cmake-utils_use_build iostats)
		$(cmake-utils_use_build lua)
		$(cmake-utils_use_build math)
		$(cmake-utils_use_build moc)
		$(cmake-utils_use_build mpd)
		$(cmake-utils_use_build ncurses)
		$(cmake-utils_use_build portmon PORT_MONITORS)
		$(cmake-utils_use_build rss)
		$(cmake-utils_use_build thinkpad IBM)
		$(cmake-utils_use_build weather-metar WEATHER_METAR)
		$(cmake-utils_use_build weather-xoap WEATHER_XOAP)
		$(cmake-utils_use_build wifi WLAN)
		$(cmake-utils_use_build iconv)
		-DBUILD_CONFIG_OUTPUT=ON
		-DBUILD_AUDACIOUS_LEGACY=OFF
		-DBUILD_BMPX=OFF
		-DBUILD_XMMS2=OFF
		-DMAINTAINER_MODE=ON
	"

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use vim-syntax; then
		insinto /usr/share/vim/vimfiles/ftdetect
		doins "${S}"/extras/vim/ftdetect/conkyrc.vim || die "doins failed"

		insinto /usr/share/vim/vimfiles/syntax
		doins "${S}"/extras/vim/syntax/conkyrc.vim|| die "doins failed"
	fi

	if use nano-syntax; then
		insinto /usr/share/nano/
		doins "${S}"/extras/nano/conky.nanorc|| die "doins failed"
	fi
}

pkg_postinst() {
	elog "You can find a sample configuration file at ${ROOT%/}/etc/conky/conky.conf."
	elog "To customize, copy it to ~/.conkyrc and edit it to your liking."
	elog
	elog "For more info on Conky's features please look at the Changelog in"
	elog "${ROOT%/}/usr/share/doc/${PF}. There are also pretty html docs available"
	elog "on Conky's site or in ${ROOT%/}/usr/share/doc/${PF}/html."
	elog
	elog "Also see http://www.gentoo.org/doc/en/conky-howto.xml"
	elog
}