build-0.3.5.ebuild

build-0.3.5.ebuild (text/plain), 1.31 KB, created by Nathan Phillip Brink (binki) (RETIRED) on 2010-01-17 04:07:33 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

DESCRIPTION="A massively-parallel software build system implemented on top of GNU make"
HOMEPAGE="http://kolpackov.net/projects/build/"
SRC_URI="ftp://kolpackov.net/pub/projects/${PN}/${PV%.?}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc examples"

DEPEND=""
RDEPEND="${DEPEND}"

src_prepare() {
	if use examples; then
		# fix examples to use installed build
		sed -i -e "s;^include.\*bootstrap.make\$;include build-${PV%.?}/bootstrap.make;" \
			examples/*/*/{*/,}build/bootstrap.make || die examples
	fi
	if use doc; then
		# separate HTML and text docs
		mkdir html || die doc
		mv documentation/*.{css,xhtml} html/ || die doc
	fi
}

src_install() {
	emake install_prefix="${D}/usr" install || die "emake install failed"

	dodoc NEWS README || die

	if use doc; then
		dohtml -A xhtml html/* || die doc
		dodoc documentation/* || die doc
	fi

	if use examples; then
		local docdir=/usr/share/doc/${PF}
		insinto ${docdir}

		# preserve symlinks and avoid cp:
		rm examples/cxx/hello/hello/build/import/libhello || die examples
		doins -r examples || die examples
		dosym ../../../libhello/build/import/libhello ${docdir}/examples/cxx/hello/hello/build/import/libhello || die examples
	fi
}