Let's try above again

cgal-3.5.1.ebuild (text/plain), 1.24 KB, created by Samuli Suominen (RETIRED) on 2010-01-08 13:18:44 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/cgal/cgal-3.3.1.ebuild,v 1.4 2009/08/12 21:29:10 bicatali Exp $

EAPI=2
CMAKE_BUILD_TYPE=Release
inherit cmake-utils

MY_P=CGAL-${PV}

DESCRIPTION="C++ library for geometric algorithms and data structures"
HOMEPAGE="http://www.cgal.org/"
SRC_URI="http://gforge.inria.fr/frs/download.php/25109/${MY_P}.tar.gz"

LICENSE="LGPL-2.1 MIT QPL"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cxx examples gmp lapack qt4"

RDEPEND="dev-libs/boost
	dev-libs/mpfr
	virtual/opengl
	x11-libs/libX11
	sys-libs/zlib
	sci-libs/taucs
	gmp? ( dev-libs/gmp
		cxx? ( dev-libs/gmp[-nocxx] ) )
	lapack? ( virtual/lapack )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

DOCS="AUTHORS CHANGES* README"

src_configure() {
	if use gmp; then
		mycmakeargs="${mycmakeargs}
			$(cmake-utils_use_with cxx GMPXX)"
	fi

	mycmakeargs="${mycmakeargs}
		-DWITH_CGAL_Qt3=OFF
		$(cmake-utils_use_with qt4 CGAL_Qt4)
		$(cmake-utils_use_with lapack CPACK)
		$(cmake-utils_use_with gmp)
		-DWITH_LEDA=OFF
		$(cmake-utils_use_with examples DEMOS)
		$(cmake-utils_use_with examples)"

	cmake-utils_src_configure
}