net-wireless/intel-wimax-network-service-1.4.0.ebuild

intel-wimax-network-service-1.4.0.ebuild (text/plain), 1.57 KB, created by Simeon Maryasin on 2010-01-05 01:41:23 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

MY_P="WiMAX-Network-Service-${PV}"

DESCRIPTION="WiMAX Network Service for Intel wimax cards"
HOMEPAGE="http://www.linuxwimax.org/"
SRC_URI="http://www.linuxwimax.org/Download?action=AttachFile&do=get&target=${MY_P}.tar.bz2
	-> ${MY_P}.tar.bz2
	yota? (
		http://icelord.net/images/wimax/NDnSAgentConfig_forDriver.xml
		http://icelord.net/images/wimax/NDnSAgentDefaultConfig.xml
	)"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE="debug +tools yota"

COMMON_DEP=">=dev-libs/libnl-1.1"
RDEPEND="${COMMON_DEP}
	=net-wireless/intel-wimax-binary-supplicant-${PV}*"
DEPEND="${COMMON_DEP}
	dev-util/pkgconfig
	tools? ( !net-wireless/intel-wimax-tools )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	if use yota; then
		einfo "Replacing NDnS config with Yota-enabled ones..."
		cp "${DISTDIR}"/NDnSAgentConfig_forDriver.xml tools_projects/Pipe/wimaxd/Agents/NDnS/NDnSAgentConfig_forDriver.xml
		cp "${DISTDIR}"/NDnSAgentDefaultConfig.xml tools_projects/Pipe/wimaxd/Agents/NDnS/NDnSAgentDefaultConfig.xml
	fi
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable tools) \
		--localstatedir=/var \
		--with-i2400m=/usr
	# we use driver from linux-headers
	# TODO: add appropriate version of linux-headers into deps
}

src_install() {
	emake install DESTDIR="${D}" || die "Install failed"

	rm "${D}/etc/init.d/wimax"

	doinitd "${FILESDIR}"/wimax
}

pkg_postinst() {
	elog "You will need to install appropriate firmware."
	elog "For Intel Link 5050 series see bug #266893."
}