games-engines/instead-1.0.4+live ebuild

instead-1.0.4.ebuild (text/plain), 1.13 KB, created by A.C.Heron on 2010-01-03 19:12:49 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit games

DESCRIPTION="INterpreter for Simple TExt ADventures"
HOMEPAGE="http://instead.googlecode.com/"

if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="http://instead.googlecode.com/svn/trunk/"
	inherit subversion
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://instead.googlecode.com/files/${P/-/_}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE=""

DEPEND="=dev-lang/lua-5.1*
	media-libs/libsdl
	media-libs/sdl-mixer
	media-libs/sdl-image
	media-libs/sdl-ttf"
RDEPEND="${DEPEND}"

src_prepare() {
	cp Rules.make.system Rules.make || die "Cannot copy Rules.make.system"
	sed -i Rules.make \
		-e 's/lua5.1/lua/' \
		-e 's:PREFIX=.*:PREFIX=/usr:' \
		-e 's:BIN=.*:BIN=$(DESTDIR)'"${GAMES_BINDIR}:" \
		-e 's:STEADPATH=$(DESTDIR)$(PREFIX)/share:STEADPATH=$(DESTDIR)'"${GAMES_DATADIR}:" \
		-e 's:DOCPATH=$(DESTDIR)$(PREFIX)/share:DOCPATH=$(DESTDIR)'"${GAMES_DATADIR}:" || die "Cannot patch Rules.make"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	prepgamesdirs
}