# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit perl-app webapp depend.php depend.apache

MY_PF="OCSNG_UNIX_SERVER-1.02.1"

DESCRIPTION="Powerful inventory and package deployment system."
HOMEPAGE="http://www.ocsinventory-ng.org/index.php?page=English"
SRC_URI="mirror://sourceforge/${PN}/${MY_PF}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
WEBAPP_MANUAL_SLOT="yes"
KEYWORDS="amd64 x86"
IUSE=""

DEPEND="dev-lang/perl"

RDEPEND="dev-perl/XML-Simple
virtual/perl-IO-Compress
dev-perl/DBI
dev-perl/DBD-mysql
dev-perl/Apache-DBI
dev-perl/Net-IP
dev-perl/SOAP-Lite
perl-gcpan/XML-Entities
www-apache/mod_perl"

need_apache2

pkg_setup() {
	perl-module_pkg_setup
	require_php_with_use mysql zip gd
	webapp_pkg_setup
}

src_prepare() {
	mv "${WORKDIR}/${MY_PF}" "${S}"
	cd "${S}"/Apache
	perl-module_src_prep

	cd "${S}"
	find ocsreports -type f -exec chmod -x {} +
	chmod 640 ocsreports/dbconfig.inc.php
	rm ocsreports/install.php
	mv ocsreports/files/ocsbase.sql .

	# Remove 'CREATE DATABASE' and 'GRANT' statements
	sed -i -e "1,2d" -e "s/^GRANT ALL.*//" ocsbase.sql

	sed -i \
		-e 's:VERSION_MP$:2:' \
		-e 's:DATABASE_SERVER$:localhost:' \
		-e 's:DATABASE_PORT$:3306:' \
		-e 's:"PATH_TO_LOG_DIRECTORY":/var/log/ocsinventory:' \
		"${S}"/Apache/etc/${PN}/${PN}-server.conf
}

src_compile() {
	cd "${S}"/Apache
	perl-module_src_compile
}

src_install() {
	cd "${S}"/Apache
	perl-module_src_install
	insinto ${APACHE_VHOSTS_CONFDIR}
	newins etc/${PN}/${PN}-server.conf ${PN}.include

	keepdir /var/log/${PN}
	fowners apache:apache /var/log/${PN}

	webapp_src_preinst
	cp -R "${S}"/ocsreports/* ${D}${MY_HTDOCSDIR}
	webapp_sqlscript mysql ${S}/ocsbase.sql
	webapp_src_install
	keepdir /var/lib/ocsinventory

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
}