ufraw-999.ebuild

ufraw-999.ebuild (text/plain), 1.85 KB, created by INODE64 Sistemas on 2009-12-05 17:59:47 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/ufraw/ufraw-0.16.ebuild,v 1.4 2009/11/21 19:32:10 nixnut Exp $

EAPI=2

inherit fdo-mime gnome2-utils autotools cvs

DESCRIPTION="RAW Image format viewer and GIMP plugin"
HOMEPAGE="http://ufraw.sourceforge.net/"
SRC_URI=""

ECVS_SERVER="ufraw.cvs.sourceforge.net:/cvsroot/ufraw"
ECVS_USER=anonymous
ECVS_PASS=

ECVS_MODULE="ufraw"


LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ppc ~ppc64 ~x86"
IUSE="exif lensfun gimp gnome gtk openmp timezone"

RDEPEND="
	media-libs/jpeg
	>=media-libs/lcms-1.13
	media-libs/tiff
	sci-libs/cfitsio
	exif? ( >=media-gfx/exiv2-0.11 )
	gnome? ( gnome-base/gconf )
	gtk? ( >=x11-libs/gtk+-2.6.0
		>=media-gfx/gtkimageview-1.5.0
		gimp? ( >=media-gfx/gimp-2.0 ) )
	lensfun? ( >=media-libs/lensfun-0.2.3 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"


S=${WORKDIR}/${ECVS_MODULE}

pkg_setup() {
	if use gimp && ! use gtk; then
		eerror "to enable gimp support, you must enable gtk support"
		die "emerge ${PN} with gtk support"
	fi
}

src_prepare() {
	eautoreconf
}

src_configure() {
	econf \
		--without-cinepaint \
		--enable-extras \
		$(use_with gimp) \
		$(use_enable gnome mime) \
		$(use_with gtk) \
		$(use_enable openmp) \
		$(use_enable timezone dst-correction)
}

src_compile() {
	emake schemasdir=/etc/gconf/schemas || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" schemasdir=/etc/gconf/schemas install || die "make install failed"
	dodoc README TODO || die "doc installation failed"
}

pkg_postinst() {
	GCONF_CONFIG_SOURCE=`gconftool-2 --get-default-source` \
	    gconftool-2 --makefile-install-rule \
	    /etc/gconf/schemas/ufraw.schemas >& /dev/null || :

	if use gnome ; then
		fdo-mime_mime_database_update
		gnome2_gconf_install
		fdo-mime_desktop_database_update
	fi
}