# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/rss2email/rss2email-2.65.ebuild,v 1.2 2009/07/26 13:57:27 rbu Exp $

EAPI=2

inherit eutils

S=${WORKDIR}/${PN}
DESCRIPTION="Web interface for rss2email"
HOMEPAGE="http://rss2email.infogami.com/"
SRC_URI="http://lindsey.smith.googlepages.com/r2eui.tar.gz"
RESTRICT="nomirror"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
DEPEND="net-mail/rss2email
	dev-python/cheetah
	>=dev-python/webpy-0.3
	virtual/python"
RDEPEND="${DEPEND}"

src_prepare() {
	# Introduce additional cmdline options
	epatch "${FILESDIR}"/r2eui-1.1-cmdline_options.patch
	# Fix for proxying with apache
	epatch "${FILESDIR}"/r2eui-1.1-template_urls.patch
}

src_install() {
	insinto /usr/share/r2eui/templates
	doins templates/ui.html
	insinto /usr/share/r2eui/static
	doins static/style.css
	insinto /usr/share/r2eui
	doins r2eui.py

	insinto /etc/rss2email
	doins "${FILESDIR}"/feeds.dat
	exeinto /usr/bin
	doexe "${FILESDIR}"/r2eui

        newinitd "${FILESDIR}"/r2eui.initd r2eui
        newconfd "${FILESDIR}"/r2eui.confd r2eui
}

pkg_postinst() {
	elog
	elog "If this is your first install of r2eui, an empty 'feeds.dat'"
	elog "has been installed in /etc/rss2email."
	elog "If you previously used the rss2email command line tool 'r2e',"
	elog "you may replace this file by your existing '~/.rss2email/feeds.dat'."
	elog
	elog "Please take a look at '/etc/conf.d/r2eui' before starting the web"
	elog "interface with '/etc/init.d/r2eui start'."
	elog
}