denemo-0.8.10.ebuild

denemo-0.8.10.ebuild (text/plain), 1.23 KB, created by Simone Scanzoni on 2009-11-15 16:53:39 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit autotools font

FONT_S="${S}/fonts"
FONTDIR="/usr/share/fonts/truetype/denemo"
FONT_SUFFIX="ttf"

DESCRIPTION="GTK+ graphical music notation editor."
HOMEPAGE="http://denemo.sourceforge.net"
SRC_URI="http://savannah.gnu.org/download/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc sparc x86"
IUSE="jack nls"

RDEPEND=">=x11-libs/gtk+-2:2
	>=dev-libs/libxml2-2.3.10
	gnome-base/librsvg
	>=media-libs/aubio-0.3.2
	>=media-libs/portaudio-19_pre
	>=dev-scheme/guile-1.8
	media-libs/alsa-lib
	>=x11-libs/gtksourceview-2.0
	jack? ( >=media-sound/jack-audio-connection-kit-0.102 )"
DEPEND="${RDEPEND}
	|| ( dev-util/yacc sys-devel/bison )
	sys-devel/flex
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

src_prepare() {
	# Wrong directory, icons is for theme sets
	sed -e 's:icons:pixmaps:g' -i src/view.c \
		-i pixmaps/Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		$(use_enable jack)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README*
	font_src_install
}