tk-8.4.4-r1 beta 1

tk-8.4.4-r1.ebuild (text/plain), 2.12 KB, created by Eamon Caddigan on 2003-11-20 18:34:02 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.4.ebuild,v 1.1 2003/10/21 18:41:52 mholzer Exp $

inherit eutils

DESCRIPTION="Tk Widget Set"
HOMEPAGE="http://dev.scriptics.com/software/tcltk/"
SRC_URI="ftp://ftp.scriptics.com/pub/tcl/tcl8_4/${PN}${PV}-src.tar.gz"

LICENSE="BSD"
SLOT="1"
KEYWORDS="~x86 ~sparc ~mips"

DEPEND=">=sys-apps/sed-4.0.5
	>=sys-apps/portage-2.0.47-r10
	virtual/x11
	=dev-lang/tcl-${PV}*"

S=${WORKDIR}/${PN}${PV}

src_unpack() {
	unpack ${A}
	cd ${S}/library
	epatch ${FILESDIR}/remove-control-v-8.4.diff || die
}

# hyper-optimizations untested...
#
src_compile() {
	cd ${S}/unix
	econf \
		--with-tcl=/usr/lib \
		--enable-threads || die
	emake CFLAGS="${CFLAGS}" || die
}

src_install() {
	#short version number
	local v1
	v1=${PV%.*}

	cd ${S}/unix
	make INSTALL_ROOT=${D} MAN_INSTALL_DIR=${D}/usr/share/man install || die

	# fix the tkConfig.sh to eliminate refs to the build directory
	sed -i \
		-e "s,^\(TK_BUILD_LIB_SPEC='-L\)${S}/unix,\1/usr/lib," \
		-e "s,^\(TK_SRC_DIR='\)${S}',\1/usr/lib/tk${v1}/include'," \
		-e "s,^\(TK_BUILD_STUB_LIB_SPEC='-L\)${S}/unix,\1/usr/lib," \
		-e "s,^\(TK_BUILD_STUB_LIB_PATH='\)${S}/unix,\1/usr/lib," \
		${D}/usr/lib/tkConfig.sh

	# install private headers
	dodir /usr/lib/tk${v1}/include/unix
	install -c -m0644 ${S}/unix/*.h ${D}/usr/lib/tk${v1}/include/unix
	dodir /usr/lib/tk${v1}/include/generic
	install -c -m0644 ${S}/generic/*.h ${D}/usr/lib/tk${v1}/include/generic
	rm -f ${D}/usr/lib/tk${v1}/include/generic/tk.h
	rm -f ${D}/usr/lib/tk${v1}/include/generic/tkDecls.h
	rm -f ${D}/usr/lib/tk${v1}/include/generic/tkPlatDecls.h

	# install symlinks for libraries and wish if no prior version is
	# installed
	#dosym /usr/lib/libtk${v1}.a /usr/lib/libtk.a
	if [ ! -f /usr/lib/libtk.so ] ; then
		dosym /usr/lib/libtk${v1}.so /usr/lib/libtk.so
	fi
	if [ ! -f /usr/lib/libtkstub.a ] ; then
		dosym /usr/lib/libtkstub${v1}.a /usr/lib/libtkstub.a
	fi
	if [ ! -f /usr/bin/wish ] ; then
		ln -sf wish${v1} ${D}/usr/bin/wish
	fi

	cd ${S}
	dodoc README changes license.terms
}