remuco-9999.ebuild

remuco-9999.ebuild (text/plain), 2.20 KB, created by James Le Cuirot on 2009-11-06 22:32:54 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit mercurial java-pkg-2 java-ant-2

EHG_REPO_URI="https://remuco.googlecode.com/hg"
S="${WORKDIR}/hg"

DESCRIPTION="A server and J2ME client to control various media players"
HOMEPAGE="http://code.google.com/p/remuco"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="amarok audacious banshee exaile mpd mplayer rhythmbox totem tvtime vlc xmms2"

DEPEND=">=virtual/jdk-1.4.2
	>=dev-java/sun-j2me-bin-2.5.2
	>=dev-java/proguard-4.3-r1
	dev-python/dbus-python
	dev-python/imaging
	dev-python/pybluez
	dev-python/pygobject
	dev-python/pyxdg
	>=dev-lang/python-2.5
	mpd? ( >=dev-python/python-mpd-0.2 )
	xmms2? ( >=media-sound/xmms2-0.5[python] )"

RDEPEND="${DEPEND}
	amarok? ( >=media-sound/amarok-2.0 )
	audacious? ( >=media-sound/audacious-1.5.1 )
	banshee? ( >=media-sound/banshee-1.4 )
	exaile? ( >=media-sound/exaile-3 )
	mpd? ( >=media-sound/mpd-0.13.2 )
	mplayer? ( media-video/mplayer )
	rhythmbox? ( >=media-sound/rhythmbox-0.11.5 )
	totem? ( >=media-video/totem-2.22 )
	tvtime? ( >=media-tv/tvtime-0.9.11 )
	vlc? ( >=media-video/vlc-0.9 )"

src_prepare() {
	local j2me=$(best_version dev-java/sun-j2me-bin)
	local proguard=$(java-pkg_getjars --build-only proguard)

	sed -r \
		-e "s:^(wtk\.home=).*:\1/opt/${j2me#*/}:" \
		-e "s:^(proguard.jar=).*:\1${proguard//:/\\:}:" \
		-e 's:^[^ ]+\.jar=\$\{microemu\.home\}:#\0:' \
		-e 's:^#([^ ]+\.jar=\$\{wtk\.home\}):\1:' \
		client/build.properties.example > client/build.properties || die
}

src_compile() {
	cd client
	eant dist
}

src_install() {
	local adapter

	export PREFIX_EXAILE="${D}/usr/"
	export PREFIX_RHYTHMBOX="${D}/usr/"
	export PREFIX_TOTEM="${D}/usr/"
	export PREFIX_XMMS2="${D}/usr/"
	export REMUCO_COMPONENTS="client"

	for adapter in ${IUSE}; do
		use ${adapter} && REMUCO_COMPONENTS="${REMUCO_COMPONENTS},${adapter}"
	done

	python setup.py install --prefix="${D}/usr/" || die
	dodoc doc/{AUTHORS,CHANGES,README,api.html,client-server-protocol.png,shutdown-system.example,volume.example} || die
}

pkg_postinst() {
	einfo "The JAR and JAD files for your mobile phone or other J2ME device can"
	einfo "be found in /usr/share/${PN}/client."
}