cronie-1.4.1.ebuild with correct setup of anacron (added init script, spool dir setup)

cronie-1.4.1-r1.ebuild (text/plain), 1.62 KB, created by Allen Brooker (AllenJB) on 2009-10-28 17:11:10 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/cronie/cronie-1.4.1.ebuild,v 1.1 2009/08/23 20:12:43 bangert Exp $

EAPI="2"

inherit cron eutils

DESCRIPTION="Cronie is a standard UNIX daemon cron based on the original vixie-cron."
SRC_URI="https://fedorahosted.org/releases/c/r/cronie/${P}.tar.gz"
HOMEPAGE="https://fedorahosted.org/cronie/wiki"

LICENSE="ISC BSD BSD-2"
KEYWORDS="~amd64 ~x86"
IUSE="anacron inotify pam"

DEPEND="anacron? ( !sys-process/anacron )
	pam? ( virtual/pam )"
RDEPEND="${DEPEND}"

#cronie supports /etc/crontab
CRON_SYSTEM_CRONTAB="yes"

src_configure() {
	ANACRON_SPOOL_DIR="/var/spool/anacron" SPOOL_DIR="/var/spool/cron/crontabs" econf \
		$(use_with inotify ) \
		$(use_with pam ) \
		$(use_enable anacron ) \
		--with-daemon_username=cron \
		--with-daemon_groupname=cron \
		|| die "econf failed"
}

src_install() {
	emake install DESTDIR="${D}" || die "install failed"

	docrondir
	fowners root:cron /usr/bin/crontab
	fperms 2750 /usr/bin/crontab

	insinto /etc
	newins "${FILESDIR}/${PN}-1.2-crontab" crontab
	newins "${FILESDIR}/${PN}-1.2-cron.deny" cron.deny

	if use anacron; then
		insinto /etc/cron.daily
		newins "${S}/contrib/0anacron" 0anacron
		fperms 0755 /etc/cron.daily/0anacron

		keepdir /var/spool/anacron
		fowners root:cron /var/spool/anacron
		fperms 0750 /var/spool/anacron

		newinitd "${FILESDIR}/anacron-1.4.1-initd" anacron
		dodoc contrib/anacrontab
	fi

	keepdir /etc/cron.d
	newinitd "${FILESDIR}/${PN}-1.2-initd" cronie
	dodoc NEWS AUTHORS README
}

pkg_postinst() {
	cron_pkg_postinst
}