My ebuild

heroes3-1.3.1a.ebuild (text/plain), 1.85 KB, created by Chris Gianelloni (RETIRED) on 2003-11-11 06:45:39 UTC

# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

IUSE="nocd"
DESCRIPTION="Heroes of Might and Magic III - turn-based 2-D medieval combat"
HOMEPAGE="http://www.lokigames.com/products/heroes3/"
SRC_URI="ftp://ftp.planetmirror.com/pub/lokigames/updates/heroes3/${P}-cdrom-x86.run"

LICENSE="LOKI-EULA"
SLOT="0"
KEYWORDS="x86"
RESTRICT="nostrip"

DEPEND="virtual/glibc"
RDEPEND="${DEPEND}
	virtual/x11"

S=${WORKDIR}

dir=${GAMES_PREFIX_OPT}/${PN}
Ddir=${D}/${dir}

pkg_setup() {
	if [ "`use nocd`" ]; then
		ewarn "The installed game takes about 342MB of space!"
	fi
	games_pkg_setup
}

src_unpack() {
	unpack_makeself
}

src_install() {
	dodir ${dir}
	games_get_cd hiscore.tar.gz
	games_verify_cd "Heroes of Might and Magic III"
	einfo "Copying files... this may take a while..."
	exeinto /opt/heroes3
	doexe ${GAMES_CD}/bin/x86/heroes3
	insinto /opt/heroes3
	doins ${GAMES_CD}/{Heroes_III_Tutorial.pdf,README,icon.{bmp,xpm}}
	if [ "`use nocd`" ]; then
		cp -r ${GAMES_CD}/{data,maps,mp3} ${Ddir} || die "copying data"
	fi
	
	cd ${Ddir}
	tar xf ${GAMES_CD}/hiscore.tar.gz

	cd ${S}
	bin/Linux/x86/loki_patch --verify patch.dat
	bin/Linux/x86/loki_patch patch.dat ${Ddir} >& /dev/null || die "patching"

	# now, since these files are coming off a cd, the times/sizes/md5sums wont
	# be different ... that means portage will try to unmerge some files (!)
	# we run touch on ${D} so as to make sure portage doesnt do any such thing
	find ${Ddir} -exec touch '{}' \;

	dodir ${GAMES_BINDIR}
	dogamesbin ${FILESDIR}/heroes3
	dosed "s:GENTOO_DIR:${dir}:" ${GAMES_BINDIR}/heroes3
	insinto /usr/share/pixmaps
	newins ${GAMES_CD}/icon.xpm heroes3.xpm

	prepgamesdirs
	make_desktop_entry heroes3 "Heroes3" "heroes3.xpm"
}

pkg_postinst() {
	einfo "To play the game run:"
	einfo " heroes3"

	games_pkg_postinst
}