gempak-5.6k.ebuild

gempak-5.6k.ebuild (text/plain), 5.55 KB, created by Donald Giuliano on 2003-11-04 03:58:51 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="GEMPAK Meteorological Plotting and Analysis Package"
HOMEPAGE="http://www.unidata.ucar.edu/packages/gempak"
LICENSE="as-is"

RDEPEND=""

DEPEND="${RDEPEND}
    x11-libs/openmotif
    !=x11-libs/lesstif"

SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc"

MY_PV="${PV:0:${#PV}-1}.${PV:${#PV}-1}"
MY_P="${PN}_upc${MY_PV}"
RESTRICT="fetch"
SRC_URI="${MY_P}.tar.gz"
S=${WORKDIR}

# Define this here so we don't have to have it more than once.
GENTOO_VARS="NAWIPS GARPHOME GARP_PATH NA_OS GEMPAK GEMPAKHOME GEMLIB GEMEXE
		GEMPDF GEMTBL GEMERR GEMHLP GEMMAPS GEMNTS GEMPARM GEMPTXT GEMGTXT
		NAWIPS_EXE NAWIPS_LIB NAWIPS_INC NAWIPS_HELP NAWIPS_TABLES
		NWX_TABLES NMAP_RESTORE MEL_BUFR MEL_BUFR_TABLES BRDGDIR
		xresources SCRIPTS_EXE GEMDATA OBS NTRANS_META TEXT_DATA SAT RAD
		RADDIR LDMDATA GOES8 GOES9 HDS MODEL SAO UPA RAW_SAO RAW_SYN RAW_UPA
		NLDN TORN_WARN TSTRM_WARN TEXT_WARN RBKGPH LP XUSERFILESEARCHPATH
		grids"

pkg_nofetch() {
	einfo "Please visit ${HOMEPAGE}"
	einfo "and place ${A} in ${DISTDIR}."
}

src_unpack() {
	export CONFIGDIR="${S}/config"
	export NAWIPS="${S}"

	unpack ${A}
	# This is necessary because the paths to some bitmaps are hard-coded.
	epatch ${FILESDIR}/gui.c.patch

	sed -e '/^GEMPAKHOME/iNAWIPS           = ${S}' ${FILESDIR}/Makeinc.common >> ${CONFIGDIR}/Makeinc.common

	# Eliminate bad symlink
	ebegin "Eliminating bad symlink"
		rm ${S}/unidata/programs/gpnexr2/rsl_colors
	eend

	# Can't install to /usr/local
	ebegin "Fixing bad install locations"
		for BADFILE in `grep -lr '/usr/local' ${S}`
			do sed -i "s:/usr/local:/usr:g" ${BADFILE} ;
		done
	eend 0

	# Replace obsoleted header
	#ebegin "Fixing obsolete header files"
	#	for OLDFILE in `grep -lr 'varargs.h' ${S}`
	#		do sed -i "s:varargs.h:stdarg.h:g" ${OLDFILE} ;
	#	done
	#eend 0
}

src_compile() {
	# All GEMPAK paths need to be unset before attempting to compile.
	unset ${GENTOO_VARS}

	# These GEMPAK paths must be set to their new values before
	# compiling.
	export CONFIGDIR="${S}/config"
	export GARPHOME="${S}/comet/garp"
	export NA_OS="linux"
	export NAWIPS="${S}"

	# This is necessary because otherwise it freaks out due to a missing
	# lib/linux.
	mkdir -p lib/linux

	make || die
}

src_install() {
	# All GEMPAK paths need to be unset before attempting to compile.
	unset ${GENTOO_VARS}

	# These GEMPAK paths must be set to their new values before
	# compiling.
	export CONFIGDIR="${S}/config"
	export GARPHOME="${S}/comet/garp"
	export NA_OS="linux"
	export NAWIPS="${S}"

	make install || die

	# Create the directory to install GEMPAK to.
	dodir usr/gempak

	# Put all the necessary files in the correct place.
	cp -Rf ${S}/* ${D}/usr/gempak

	# Makefile cleanup
	rm ${D}/usr/gempak/Makefile
	rm ${D}/usr/gempak/gempak/Makefile
	rm ${D}/usr/gempak/comet/Makefile
	rm ${D}/usr/gempak/comet/garp/Makefile

	# This eliminates all the source code, header files, and sundry other
	# useless files.
	rm -rf ${D}/usr/gempak/config
	rm -rf ${D}/usr/gempak/include
	rm -rf ${D}/usr/gempak/ldm
	rm -rf ${D}/usr/gempak/lib
	rm -rf ${D}/usr/gempak/netcdf
	rm -rf ${D}/usr/gempak/nprogs
	rm -rf ${D}/usr/gempak/unidata
	rm -rf ${D}/usr/gempak/versions
	rm -rf ${D}/usr/gempak/gempak/source
	rm -rf ${D}/usr/gempak/comet/dcshef
	rm -rf ${D}/usr/gempak/comet/etamap
	rm -rf ${D}/usr/gempak/comet/garp/gempak
	rm -rf ${D}/usr/gempak/comet/garp/gui
	rm -rf ${D}/usr/gempak/comet/garp/include
	rm -rf ${D}/usr/gempak/comet/garp/init
	rm -rf ${D}/usr/gempak/comet/garp/object
	rm -rf ${D}/usr/gempak/comet/garp/util

	# This is necessary, because otherwise some of the files will not be
	# world-readable
	ebegin "Fixing permissions to ensure world-readability"
		chmod +r -Rf ${D}
	eend

	# One of the GEMPAK cleanup scripts uses '$RM' instead of 'rm'.
	sed -e 's/^\$RM/rm/' ${S}/bin/scripts/cleanvgf > ${D}/usr/gempak/bin/scripts/cleanvgf
	insinto /usr/gempak
	doins ${FILESDIR}/Gemenviron.{bash,tcsh}
}

pkg_postinst() {
	einfo "To use GEMPAK, you'll need to run the command"
	einfo "\"source /usr/gempak/Gemenviron.bash\", which will"
	einfo "set the appropriate environmental variables.  If you"
	einfo "prefer tcsh, a Gemenviron.tcsh file is included as well."
	einfo ""
	einfo "To use some of the GUI GEMPAK tools (such as Garp),"
	einfo "it is necessary to create the requisite directory hierarchy"
	einfo "in \$GEMDATA.  To auto-create a skeleton directory hierarchy, run"
	einfo "\"ebuild /var/db/pkg/app-sci/${PN}/${PF}.ebuild config \$GEMDATA\","
	einfo "where \$GEMDATA is your directory of choice."
	einfo "Note that the default \$GEMDATA directory is /data/gempak,"
	einfo "and if you wish to use something different you will have"
	einfo "to edit the Gemenviron.bash and/or Gemenviron.tcsh files"
	einfo "to reflect the change."
	einfo ""
	einfo "NOTE:  Some of the programs in the GEMPAK suite have paths"
	einfo "hardcoded into the executables, so it is ill-advised to"
	einfo "start playing around with paths unless you really know"
	einfo "what you are doing."
}

pkg_config() {
	GEMDATADIR=${1}
 
	if [ -z ${GEMDATADIR} ] ; then
		echo "usage: ebuild /var/db/pkg/app-sci/${PN}/${PF}.ebuild config [gemdatadir]"
		die
	fi
 
	mkdir ${GEMDATADIR}/images/radar/nids -p
	mkdir ${GEMDATADIR}/images/sat/GOES-East -p
	mkdir ${GEMDATADIR}/meta
	mkdir ${GEMDATADIR}/model
	mkdir ${GEMDATADIR}/nldn
	mkdir ${GEMDATADIR}/nwx
	mkdir ${GEMDATADIR}/redbook
	mkdir ${GEMDATADIR}/surface
	mkdir ${GEMDATADIR}/upperair
	ln -s model ${GEMDATADIR}/hds
	ln -s model ${GEMDATADIR}/hrs
 
	echo "Created skeleton GEMDATA directory in ${GEMDATADIR}."
}