fdm-1.5 (updated deps)

fdm-1.5.ebuild (text/plain), 932 bytes, created by Dennis Schridde on 2009-08-25 19:13:18 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=2

inherit eutils

DESCRIPTION="fetch, filter and deliver mail"
HOMEPAGE="http://fdm.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~ia64"
IUSE="pcre"

DEPEND="dev-libs/openssl
	|| ( dev-libs/tdb net-fs/samba-libs )
	pcre? ( dev-libs/libpcre )"
RDEPEND="${DEPEND}"

src_prepare() {
	sed -i "${S}"/GNUmakefile \
		-e 's/$(LIBS) -o $@ $+/-o $@ $+ $(LIBS)/' \
		|| die
}

src_compile() {
	emake -j1 \
		PCRE=$(use pcre && echo 1)
}

src_install() {
	dobin fdm || die "Installing binary failed"
	doman fdm.1 fdm.conf.5 || die "Installing man pages failed"

	dodoc CHANGES MANUAL README TODO || die "Installing documentation failed"

	docinto examples
	dodoc examples/* || die "Installing documentation failed"
}

pkg_postinst() {
	enewuser fdm
}