# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit eutils confutils

DESCRIPTION="Redmine is a flexible project management web application written using Ruby on Rails framework"
HOMEPAGE="http://www.redmine.org/"
SRC_URI="mirror://rubyforge/${PN}/${P}.tar.gz"

KEYWORDS="~amd64 ~x86"
LICENSE="GPL-2"
SLOT="0"
IUSE="cvs darcs git imagemagick mercurial mysql postgres sqlite3 subversion"

DEPEND=">=dev-ruby/rails-2.1.2
	>=dev-ruby/activerecord-2.1[mysql?,postgres?,sqlite3?]
	imagemagick? ( dev-ruby/rmagick )"

RDEPEND="${DEPEND}
	>=dev-ruby/actionwebservice-1.1.3
	>=dev-ruby/ruby-net-ldap-0.0.4
	>=dev-ruby/coderay-0.7.6.227
	cvs? ( >=dev-util/cvs-1.12 )
	darcs? ( dev-util/darcs )
	git? ( dev-util/git )
	mercurial? ( dev-util/mercurial )
	subversion? ( >=dev-util/subversion-1.3 )"

REDMINE_DIR="/var/lib/${PN}"

pkg_setup() {
	confutils_require_any mysql postgres sqlite3

	enewgroup redmine
	# home directory is required for SCM.
	enewuser  redmine -1 -1 "${REDMINE_DIR}" redmine
}

src_prepare() {
	rm -fr log files/delete.me
	rm -fr vendor/plugins/actionwebservice
	rm -fr vendor/plugins/coderay-0.7.6.227
	rm -fr vendor/plugins/ruby-net-ldap-0.0.4
}

src_install() {
	dodoc doc/{CHANGELOG,INSTALL,UPGRADING}
	rm -fr doc

	mv config/database.yml{.example,}
	mv config/email.yml{.example,}

	insinto /etc/${PN}
	doins -r config/*
	rm -rf config

	dosym /etc/${PN}/ "${REDMINE_DIR}/config"
	keepdir /var/log/${PN}
	dosym /var/log/${PN}/ "${REDMINE_DIR}/log"

	insinto "${REDMINE_DIR}"
	# This avoid cp warning with symbolic link
	rm -f "vendor/rails/actionpack/test/fixtures/layout_tests/layouts/symlinked"
	doins -r . || die
	dosym ../../symlink_parent "${REDMINE_DIR}/vendor/rails/actionpack/test/fixtures/layout_tests/layouts/symlinked"
	keepdir "${REDMINE_DIR}/files"

	fowners -R redmine:redmine \
		"${REDMINE_DIR}/files" \
		"${REDMINE_DIR}/tmp" \
		/var/log/${PN} || die
	fowners redmine:redmine /etc/${PN}/environment.rb || die
	# for SCM
	fowners redmine:redmine "${REDMINE_DIR}" || die
	
	newconfd "${FILESDIR}/redmine.confd" redmine
        newinitd "${FILESDIR}/redmine.initd" redmine
}

pkg_postinst() {

	einfo
	elog "Installation notes are at official site"
	elog "http://www.redmine.org/wiki/redmine/RedmineInstall"
	elog
	elog "For upgrade instructions take a look at:"
	elog "http://www.redmine.org/wiki/redmine/RedmineUpgrade"
	einfo
}