Gemenviron.tcsh: GEMPAK configuration file

Gemenviron.tcsh (text/plain), 6.59 KB, created by Donald Giuliano on 2003-11-03 01:19:38 UTC

# Gemenviron file for GEMPAK 5.6
#
#		Sets environment variables used in running GEMPAK
#		UNIDATA Program Center 6/1/92 (PB)
#		Revised 8/31/94 for GEMPAK 5.2
#		Modified 12/95 for Gempak5.2.1/Nawips (Chiz)
#               Modified  8/96 for Gempak5.4/NAWIPS (Chiz)
#               Modified 10/00 for Gempak5.6/NAWIPS (Chiz)
#---------------------------------------------------------------------
#  The command
#               source Gemenviron
#
#  or the individual lines below, must be included in your .login or 
#  .cshrc file!
#---------------------------------------------------------------------
# <<CONFIGURE>>
# To build GEMPAK on your system, you should set the NAWIPS variable 
# below to the top level of the source distribution tree on your system.
#
#  Please configure the following definitions to reflect your system:
#
# Top level directory:
   setenv NAWIPS /usr/local/gempak
#
# Path for Garp tables and configuration. You should only have to
# modify GARP_PATH if you have unique Garp_defaults for specifc
# data sets, such as case studies. In those cases, creating
# a ntl.case startup script which sets those local environmental variables
# is generally the best solution.
#
   setenv GARPHOME $NAWIPS/comet/garp
   setenv GARP_PATH $GARPHOME/config
#
#
# Uncomment the following line for using GCC compilers (Solaris only)
# set USEGCC_SOL=1
#
# --------------------------------------------------------------------
# Make sure NAWIPS directory exists
#
if ( ! -d $NAWIPS ) then
        echo "Can not find NAWIPS distribution."
        echo 'Check Gemenviron NAWIPS definition ->' $NAWIPS
        unsetenv NAWIPS
        exit
endif

#try to determine operating system: command uname must be in path
#
if($?NA_OS == 0) then
   set TMP_OS=`uname -s | tr '[A-Z]' '[a-z]'`
   switch ($TMP_OS)
        case "aix":
           setenv NA_OS "aix"
           breaksw
        case hp-ux:
	   set OS_MAJOR=`uname -r | cut -f1,2 -d.`
           if($OS_MAJOR == 'B.11') then
              setenv XCFLAGS "-DSYSLOG_RETURNS_INT"
           endif
           setenv NA_OS "hpux"
           breaksw
        case irix64:
           setenv XCFLAGS "-o32"
        case irix:
           setenv NA_OS "irix"
           breaksw
        case osf1:
           setenv NA_OS "osf"
           uac p noprint # supress warnings in xw driver for unaligned access
           breaksw
        case sunos:
           set OS_MAJOR=`uname -r | sed 's/\..*//'`
           set HARDWARE=`uname -i | tr '[A-Z]' '[a-z]'`
           setenv NA_OS "sunos"
           if(($OS_MAJOR == 5)&&($?USEGCC_SOL)) then
              setenv NA_OS "sol_gcc"
	   else
              setenv NA_OS "sol"
           endif
           if(($NA_OS == 'sol')&&($HARDWARE == 'i86pc')) then
              setenv NA_OS "x86"
           endif
           breaksw
        case ultrix:
           setenv NA_OS "ultrix"
           breaksw
	case linux:
	   setenv NA_OS "linux"
	   breaksw
        case default:
           echo "trouble determining operating system configuration"
           echo "OS reported $TMP_OS"
           exit
   endsw
endif

# --------------------------------------------------------------------
#
# GEMPAK directory:
#
   setenv GEMPAK $NAWIPS/gempak
   setenv GEMPAKHOME $NAWIPS/gempak
#
# CONFIGURATION directory
   setenv CONFIGDIR $NAWIPS/config
#
# Directory for storing object libraries (GEMPAK + related software):
#
   setenv GEMLIB    $NAWIPS/lib/${NA_OS}
#
# Directory for executables (GEMPAK + related software):
#
   setenv GEMEXE    $NAWIPS/bin/${NA_OS}
#
# Remaining directories used by GEMPAK  (leave as is):
#
   setenv GEMPDF    $GEMPAK/pdf
   setenv GEMTBL    $GEMPAK/tables
   setenv GEMERR    $GEMPAK/error
   setenv GEMHLP    $GEMPAK/help
   setenv GEMMAPS   $GEMPAK/maps
   setenv GEMNTS    $GEMPAK/nts
   setenv GEMPARM   $GEMPAK/parm
   setenv GEMPTXT   $GEMPAK/txt/programs
   setenv GEMGTXT   $GEMPAK/txt/gemlib
#
#  NAWIPS specific directories
#
   setenv NAWIPS_EXE	$GEMEXE
   setenv NAWIPS_LIB	$GEMLIB
   setenv NAWIPS_INC	$NAWIPS/include
   setenv NAWIPS_HELP  	$NAWIPS/help
   setenv NAWIPS_TABLES	$NAWIPS/tables
   setenv NWX_TABLES	$NAWIPS_TABLES/nwx
   setenv NMAP_RESTORE  $GEMNTS/nmap/restore
#
#  MEL_BUFR environment
   setenv MEL_BUFR             $GEMPAK/source/melbufr
   setenv MEL_BUFR_TABLES      $GEMPAK/tables/melbufr
#
#
   setenv BRDGDIR   $NAWIPS/unidata/ldmbridge
#
# Add NAWIPS to the X applications resource path.
#
set xresources=""

if ( -d $NAWIPS/resource ) then
        set xresources="$NAWIPS/resource/%N"
        if ( $?XUSERFILESEARCHPATH ) then
           setenv XUSERFILESEARCHPATH ${xresources}:${XUSERFILESEARCHPATH}
        else
           setenv XUSERFILESEARCHPATH $xresources
        endif
endif

#
# 
# Set PATH to include $GEMEXE
#
setenv SCRIPTS_EXE   $NAWIPS/bin/scripts
setenv PATH ${PATH}:${GEMEXE}:${SCRIPTS_EXE}

#
# --------------------------------------------------------------------
# <<CONFIGURE>>
# Data directories, either real time or the Hurricane Bob sample data set:
#
#  setenv GEMDATA       $GEMPAK/data
   setenv GEMDATA       /data/gempak
   setenv OBS           $GEMDATA
#
# Location of meta files (generated with NC decide driver)
   setenv NTRANS_META	$GEMDATA/meta
#
# Location of text bulletins for use with NWX
   setenv TEXT_DATA	$GEMDATA/nwx
#
#   These are used by NAFOS (not supported by Unidata)
#   setenv AFOS_BITMAPS  $NAWIPS/nprogs/afos/bitmaps
#   setenv AFOS_DATA     $NAWIPS/tmp
#   setenv AFOS_LOG      $NAWIPS/tmp
#   setenv AFOS_BIN      $NAWIPS/tmp

#   Used by Nalarm (path component /nawips is added automatically by program). 
#   Write products into $GEMDATA/alarms/nawips for display.
    setenv AFOS_ALARMS   $GEMDATA/alarms/
#
#  Location of NSAT directory tree "Required!!"...must exist
#
   setenv SAT  		$GEMDATA/images/sat
   setenv RAD		$GEMDATA/nexrad
#
#
# Below follow  variables for data locations (site specific)
# Not required for NAWIPS, but may be used in scripts etc.
#
   setenv LDMDATA	/data/ldm
   setenv GOES8		$SAT/GOES-8
   setenv GOES9		$SAT/GOES-9
   setenv HDS           $GEMDATA/hds
   setenv MODEL         $GEMDATA/model
   setenv SAO		$GEMDATA/surface
   setenv UPA		$GEMDATA/upperair
   setenv RAW_SAO       $LDMDATA/surface/sao
   setenv RAW_SYN       $LDMDATA/surface/syn
   setenv RAW_UPA       $LDMDATA/upperair
   setenv NLDN          $GEMDATA/nldn

   setenv TORN_WARN     $TEXT_DATA/watch_warn/torn_warn
   setenv TSTRM_WARN    $TEXT_DATA/watch_warn/tstrm_warn
   setenv TEXT_WARN     $TEXT_DATA/watch_warn

   setenv RBKGPH	$GEMDATA/redbook

   if($?HOME) then
      setenv GRPHGD $HOME
   else
      setenv GRPHGD $GEMPAK
   endif
#
#  Print command and flags for systems
   setenv LP "lp -c"
   setenv LPFLAG "-d"