# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/iulib/iulib-0.3.ebuild,v 1.1 2008/11/02 06:58:28 vapier Exp $

inherit eutils autotools

DESCRIPTION="easy-to-use image and video I/O functions"
HOMEPAGE="http://code.google.com/p/iulib/"
# SRC_URI="http://iulib.googlecode.com/files/${P}.tar.gz"
SRC_URI="http://ocropus.googlecode.com/files/ocropus-${PV}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# sdl: try to test sdl
IUSE="sdl"

DEPEND="sys-libs/zlib
	media-libs/libpng
	media-libs/jpeg
	media-libs/tiff
	sdl? ( media-libs/libsdl )"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	mv "`echo ${S} | sed 's:work/iulib:work/ocropus-'"${PV}"'/iulib:'`" "${S}"
	cd ${S}
	# to make sdl really optionnal. Otherwise, if sdl is checked bad,
	#   libiulibs.a lacks dsection_set and dactive, breaking ocropus-0.4.ebuild
	#   and all other compilations including /usr/include/iulib/iulib.h
	epatch "${FILESDIR}"/utils.dgraphics_nosdl.cc.patch
	# epatch "${FILESDIR}"/${P}-install.patch # change ignored about README
	python ./genAM.py > Makefile.am
	eautomake
}

src_compile() {
	econf $(use_with sdl SDL) || die
	sed -e 's%DEFAULT_INCLUDES = -I.%DEFAULT_INCLUDES = -I. -I./imgbits -I./vidio -I./utils%' -i Makefile
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install-am || die
	dodoc CHANGES README TODO
}