ebuild; changed halibut dep

sgt-puzzles-8605.ebuild (text/plain), 1.75 KB, created by lumato on 2009-08-14 02:03:43 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit eutils games

DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
SRC_URI="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-r${PV}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND="x11-libs/gtk+:2"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( >=app-doc/halibut-1.0 )"

S="${WORKDIR}/puzzles-r${PV}"

src_compile() {
	emake CFLAGS="-ansi -pedantic -Wall -Werror -I. -Iicons $(pkg-config \
	--cflags gtk+-2.0) ${CFLAGS}" XLDFLAGS="$(pkg-config --libs gtk+-2.0)" \
	|| die "emake failed"
	if use doc ; then
		halibut --text --html --info --pdf --ps puzzles.but
	fi
}

src_install() {
	local file name size
	dodir "${GAMES_BINDIR}" || die "dodir failed"
	emake DESTDIR="${D}" gamesdir="${GAMES_BINDIR}" install \
	|| die "emake install failed"
	prepgamesdirs || die "prepgamesdir failed"
	for file in *.R ; do
		name="$(sed -n 's/^[a-z.]\+://p' "${file}")"
		test -z "${name}" && continue
		file="${file%.R}"
		for size in 16 32 48 ; do
			insinto "/usr/share/icons/hicolor/${size}x${size}/apps" || \
				die "insinto failed"
			newins "icons/${file}-${size}d24.png" "${file}.png" || \
				die "newins failed"
		done
		dosym "/usr/share/icons/hicolor/48x48/apps/${file}.png" \
			"/usr/share/pixmaps/${file}.png" || die "dosym failed"
		make_desktop_entry "${file}" "${name}" "${file}" || \
			die "cannot make desktop entry"
	done
	dodoc README HACKING || die "dodoc failed"
	if use doc ; then
		dohtml *.html || die "dohtml failed"
		doinfo puzzles.info || die "doinfo failed"
		dodoc puzzles.txt puzzles.pdf puzzles.ps || die "dodoc failed"
	fi
}