CSL 0.8 ebuild

csl-0.8.ebuild (text/plain), 961 bytes, created by Paul Hartman on 2009-08-11 14:44:28 UTC

inherit wxwidgets

DESCRIPTION="Tool to monitor Cubeengine based servers."
HOMEPAGE="http://cubelister.sourceforge.net/"
SRC_URI="mirror://sourceforge/cubelister/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="unicode geoip"
# nls is required, not optional 

RDEPEND="virtual/libintl"
DEPEND=">=x11-libs/wxGTK-2.8.0
	geoip? ( >=dev-libs/geoip-1.4.2 )
	sys-devel/gettext"

src_compile() {
	local myconf
	export WX_GTK_VER="2.8"

	if use unicode; then
		need-wxwidgets unicode
	else
		need-wxwidgets ansi
	fi

	myconf="${myconf} --with-wx-config=${WX_CONFIG}"

	if use geoip ; then
		geoip_datadir="${ROOT}/usr/share/GeoIP/"
		myconf="${myconf} --with-geoip-datadir=${geoip_datadir}"
			# --without not supported, can't use use_with
	fi

	econf \
		${myconf} \
		$(use_enable unicode) \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"

	dodoc AUTHORS ChangeLog
}