# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

DESCRIPTION="Music sequencing library for media-sound/aldrin"
HOMEPAGE="http://code.google.com/p/armstrong/"
SRC_URI="http://armstrong.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa dssi jack ladspa oss sse2"

RDEPEND="
	>=dev-lang/python-2.5
	dev-python/ctypes
	dev-python/pygtk:2
	dev-python/librsvg-python
	gnome-base/librsvg
	sys-libs/zlib
	>=media-libs/libsndfile-1.0.17
	>=media-libs/libsamplerate-0.1.3
	sci-libs/fftw:3.0
	alsa? ( media-libs/alsa-lib )
	oss? ( media-libs/alsa-oss )
	jack? ( media-sound/jack-audio-connection-kit )
	!media-libs/libzzub"
DEPEND="
	>=sys-devel/gcc-4.0.1
	>=dev-util/scons-0.97
	${RDEPEND}"

S="${WORKDIR}/${PN}"

use_truefalse() {
	if use $1; then echo True; else echo False; fi
}

src_configure() {
	scons configure PREFIX=/usr LUNAR=True \
		JACK=`use_truefalse jack` \
		OSS=`use_truefalse oss` \
		ALSA=`use_truefalse alsa` \
		SSE2=`use_truefalse sse2` \
		LADSPA=`use_truefalse ladspa` \
		DSSI=`use_truefalse dssi` \
		|| die "failed configure"
}

src_compile() {
	scons || die "failed compile"
}

src_install() {
	scons install DESTDIR="${D}" || die "failed install"
}