# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit libtool

DESCRIPTION="An OSF/Motif(R) clone"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
HOMEPAGE="http://www.lesstif.org/"
LICENSE="LGPL-2"
#KEYWORDS="~x86 ~ppc ~sparc"
KEYWORDS="-*"
SLOT="0"

DEPEND="virtual/glibc
        media-libs/freetype
        virtual/x11"


src_unpack()
{
	unpack ${A}
	cd ${S}

	ebegin "patching mwm/mwm.c (class name)"
	LC_ALL="C" sed -i\
	  -e 's:\(toplevel = XtVaAppInitialize.*\)Mwm\(.*\):\1Mwm-lesstif\2:'\
	  "${S}/clients/Motif-1.2/mwm/mwm.c"
	eend $? || die

	ebegin "patching mwm/pager.c (class name)"
	LC_ALL="C" sed -i\
	  -e 's:\"Mwm\":\"Mwm-lesstif\":'\
	  "${S}/clients/Motif-1.2/mwm/pager.c"
	eend $?  || die

	elibtoolize
}

src_compile()
{
	econf \
	  --prefix=/usr/lesstif \
	  --mandir=/usr/lesstif/man \
	  --enable-build-12 \
	  --disable-build-20 \
	  --disable-build-21 \
	  --enable-static \
	  --enable-shared \
	  --enable-production \
	  --enable-verbose=no \
	  --with-x || die "./configure failed"
	emake CFLAGS="${CFLAGS}" || die
}

src_install()
{
	make DESTDIR=${D} install || die "make install"
	prepman "/usr/lesstif"

	dodir "/usr/lib"
	for lib in libMrm.so.1 libMrm.so.1.0.2 \
	           libUil.so.1 libUil.so.1.0.2 \
	           libXm.so.1  libXm.so.1.0.2
	do
		dosym "../lesstif/lib/${lib}"\
		      "/usr/lib/${lib}" || die "symlinking ${lib}"
	done

	dodir "/usr/bin"
	dosym "../lesstif/bin/mwm"\
	      "/usr/bin/mwm-lesstif" || die

	dodir "/etc/X11"
	mv "${D}/usr/lesstif/lib/X11/mwm"\
	   "${D}/etc/X11/mwm-lesstif" || die
	dosym "../../../../etc/X11/mwm-lesstif"\
	      "/usr/lesstif/lib/X11/mwm" || die

	dodir "/etc/X11/app-defaults"
	mv "${D}/usr/lesstif/lib/X11/app-defaults/Mwm"\
	   "${D}/etc/X11/app-defaults/Mwm-lesstif" || die
	rmdir "${D}/usr/lesstif/lib/X11/app-defaults"

	dodir "/usr/share/doc"
	dosym "../../lesstif/LessTif"\
	      "/usr/share/doc/${PF}" || die "linking docs"
}