# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit autotools eutils

DESCRIPTION="GNUsound is a multitrack sound editor for GNOME environment"
HOMEPAGE="http://gnusound.sourceforge.net"
SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2
	mirror://gentoo/${PN}-0.7.4-m4-1.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="3dnow cpudetection +libsamplerate mmx sse"

RDEPEND="libsamplerate? ( media-libs/libsamplerate )
	media-libs/alsa-lib
	>=gnome-base/libgnomeui-2
	>=gnome-base/libglade-2
	media-libs/audiofile
	media-libs/libvorbis
	media-libs/libogg
	media-libs/libtheora
	media-sound/gsm
	media-libs/flac
	media-sound/jack-audio-connection-kit
	media-libs/libsndfile
	media-video/ffmpeg
	media-sound/lame"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${P}-install_target_directories.patch \
		"${FILESDIR}"/${P}-ffmpeg_headers.patch \
		"${FILESDIR}"/${P}-x86_64.patch \
		"${FILESDIR}"/${P}-flac.patch
	cp "${WORKDIR}"/m4/* config || die "cp failed"
	AT_M4DIR="config" eautoreconf
}

src_configure() {
	local myconf="--disable-fastmemcpy"
	use mmx && use sse && use 3dnow && myconf="--enable-fastmemcpy"

	econf \
		--disable-dependency-tracking \
		$(use_enable cpudetection cpudetect) \
		$(use_enable mmx fastminmax) \
		$(use_with libsamplerate) \
		--with-gnome2 \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc CHANGES NOTES README TODO
}