Cleaned up ebuild

libhl-2.1.1-r1.ebuild (text/plain), 1.27 KB, created by Michał Górny on 2009-07-24 09:30:56 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils multilib toolchain-funcs versionator

MY_PV="${PV//./}"

DESCRIPTION="A package abstraction library for Half-Life"
HOMEPAGE="http://nemesis.thewavelength.net/index.php?p=35"
SRC_URI="http://nemesis.thewavelength.net/files/files/hllib${MY_PV}.zip"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="hlextract" # XXX: tools, utils, examples?

DEPEND=""
RDEPEND=""

src_prepare() {
	epatch "${FILESDIR}"/fixes_for_2.1.0.patch
}

src_compile() {
	emake -C HLLib all || die "Failed to build libhl"

	if use hlextract; then
		cd HLExtract
		ln -s ../lib/HLLib.h hl.h
		ln -s ../HLLib/libhl.so.${PV} libhl.so
		"$(tc-getCC)" ${CFLAGS} -I. -L. Main.c -o hlextract -lhl || die "Failed to build hlextract"
	fi
}

src_install() {
	dolib HLLib/libhl.so.${PV} || die 'dolib failed'
	dosym libhl.so.${PV} /usr/$(get_libdir)/libhl.so.$(get_version_component_range 1) || die 'dosym failed'
	dosym libhl.so.${PV} /usr/$(get_libdir)/libhl.so || die 'dolib failed'

	insinto /usr/include
	newins lib/HLLib.h hl.h || die 'newins failed'

	if use hlextract; then
		dobin HLExtract/hlextract || die 'dobin failed'
	fi

	dodoc Readme.txt || die 'dodoc failed'
}