# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit cvs eutils

#MY_P
DESCRIPTION="motion picture editing tool used for painting and retouching of movies"
HOMEPAGE="http://www.cinepaint.org/"
SRC_URI=""
ECVS_SERVER="cinepaint.cvs.sourceforge.net:/cvsroot/cinepaint"
ECVS_MODULE="cinepaint-project/cinepaint"
ECVS_BRANCH="HEAD"
ECVS_AUTH="pserver"
ECVS_USER="anonymous"
ECVS_PASS=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gutenprint png zlib"

RDEPEND="x11-libs/gtk+:2
	png? ( >=media-libs/libpng-1.2 )
	zlib? ( sys-libs/zlib )
	gutenprint? ( >=net-print/gutenprint-5.0.0 )
	media-libs/openexr
	>=media-libs/lcms-1.16
	media-libs/tiff
	media-libs/jpeg
	x11-libs/fltk:1.1[opengl]
	x11-libs/libXmu
	x11-libs/libXinerama
	x11-libs/libXpm"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/cvs
	x11-proto/xineramaproto"

S=${WORKDIR}/${ECVS_MODULE}
RESTRICT=""

#DOCS=""

src_prepare() {
	epatch "${FILESDIR}/${P}-gcc43.patch"
	epatch "${FILESDIR}/${P}-multiple_parameters_named.patch"
	epatch "${FILESDIR}/${P}-implicitdecls.patch"
	epatch "${FILESDIR}/${P}-rpath.patch"
	einfo "running autogen.sh from cvs"
	chmod a+x ./autogen.sh || die "chmod a+x ./autogen.sh in ${S} failed"
	./autogen.sh || die "execution of ./autogen.sh in ${S} failed"
}

src_configure() {
	econf $(use_enable gutenprint print) --enable-gtk2
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS BUGS NEWS README TODO tips.txt
}