# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/safecopy/safecopy-1.3.ebuild,v 1.2 2009/05/27 15:30:45 scarabeus Exp $

EAPI=2
inherit autotools

DESCRIPTION="Data recovery tool to fault-tolerantly extract data from damaged (io-errors) devices or files."
HOMEPAGE="http://safecopy.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND=""
DEPEND="sys-apps/findutils
	sys-apps/grep
	sys-apps/sed"

src_prepare() {
	if use test; then
		cd "${S}"/test
		sed -i -e 's:bin/sh:bin/bash:' test.sh || die "sed failed"
		cd "${S}"/test/libsafecopydebug
		eautoreconf
	fi
	cd "${S}"
	eautoreconf
}

src_configure() {
	econf
	if use test; then
		cd "${S}"/test/libsafecopydebug
		econf
	fi
}

src_compile() {
	emake || die "emake failed"
	if use test; then
		cd "${S}"/test/libsafecopydebug
		emake || die "emake failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README || die "dodoc failed"
}

src_test() {
	cd "${S}"/test
	./test.sh || die "./test.sh failed"
}