# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit base eutils autotools

DESCRIPTION="Data recovery tool to fault-tolerantly extract data from damaged (io-errors) devices or files."
HOMEPAGE="http://safecopy.sourceforge.net"
SRC_URI="mirror://sourceforge/safecopy/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND=""
DEPEND="test? ( sys-apps/findutils sys-apps/grep sys-apps/coreutils sys-apps/sed )"

src_prepare() {
	base_src_prepare
	if use test ; then
		cd "${S}"/test/libsafecopydebug
		eautoreconf
	fi
	cd "${S}"
	eautoreconf
}

src_configure() {
	base_src_configure
	if use test ; then
		cd "${S}"/test/libsafecopydebug
		econf
	fi
}

src_compile() {
	base_src_compile
	if use test ; then
		cd "${S}"/test/libsafecopydebug
		emake || die "Testsuite compilation failed"
	fi
}

src_install() {
	base_src_install
	dodoc README || die "copying documentation failed"
}

src_test() {
	cd "${S}"/test/
	ebegin "Running safecopy self test..."
	./test.sh
	eend $? || die "Test run failed"
}