new dependency on media-libs/jpeg

abiword-2.7.6.ebuild (text/plain), 2.18 KB, created by Thorsten Vollmer on 2009-07-09 18:31:53 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit alternatives autotools gnome2 versionator

MY_MAJORV=$(get_version_component_range 1-2)

DESCRIPTION="Fully featured yet light and fast cross platform word processor"
HOMEPAGE="http://www.abisource.com/"
SRC_URI="http://www.abisource.com/downloads/${PN}/${PV}/source/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug gnome spell"

RDEPEND="sys-libs/zlib
	>=dev-libs/glib-2.16
	>=x11-libs/gtk+-2.14
	>=x11-libs/pango-1.2[X]
	>=x11-libs/cairo-1.8[X]
	media-libs/jpeg
	>=media-libs/libpng-1.2
	>=media-libs/fontconfig-2.1
	>=app-text/wv-1.2
	>=dev-libs/fribidi-0.10.4
	dev-libs/expat
	>=gnome-base/librsvg-2.16
	>=gnome-extra/libgsf-1.14.9
	spell? ( >=app-text/enchant-1.2 )
	gnome? ( >=gnome-extra/gucharmap-2
		 >=x11-libs/goffice-0.6:0.6 )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable debug)
		$(use_enable spell)
		--enable-print
		--with-gio
		--without-gnomevfs
		$(use_with gnome goffice)
		$(use_with gnome gucharmap)
		--enable-default-plugins"   # include OpenDocument import/export
}

src_prepare() {
	gnome2_src_prepare

	# install icon to pixmaps (bug #220097)
	sed 's:icondir= $(datadir)/icons:icondir = $(datadir)/pixmaps:' \
		-i Makefile.am || die "sed 1 failed"
	# readme.txt will be installed using dodoc
	sed '/readme\.txt\|abw/d' \
		-i user/wp/Makefile.am || die "sed 2 failed"
	# remove macros for compatibility with libtool-1
	rm -v libtool.m4 lt* || die "removing libtool macros failed"

	eautoreconf
}

src_install() {
	gnome2_src_install

	sed "s:Exec=abiword:Exec=abiword-${MY_MAJORV}:" \
		-i "${D}"/usr/share/applications/abiword.desktop || die "sed 3 failed"

	mv "${D}/usr/bin/abiword" "${D}/usr/bin/AbiWord-${MY_MAJORV}"
	dosym AbiWord-${MY_MAJORV} /usr/bin/abiword-${MY_MAJORV}

	dodoc AUTHORS user/wp/readme.txt
}

pkg_postinst() {
	gnome2_pkg_postinst

	alternatives_auto_makesym "/usr/bin/abiword" "/usr/bin/abiword-[0-9].[0-9]"
}

pkg_postrm() {
	gnome2_pkg_postrm

	alternatives_auto_makesym "/usr/bin/abiword" "/usr/bin/abiword-[0-9].[0-9]"
}