an ebuild for the latest squashfs lzma (3.4).

squashfs-lzma-tools-3.4.ebuild (text/plain), 2.04 KB, created by jpike on 2009-07-01 21:36:16 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/squashfs-tools-3.4.ebuild,v 1.2 2008/10/15 03:05:19 jer Exp $

inherit toolchain-funcs

MY_PV=${PV/_p/-r}
DESCRIPTION="Tool for creating compressed filesystem type squashfs with lzma compression"
HOMEPAGE="http://www.squashfs-lzma.org"
SRC_URI="ftp://ftp.slax.org/source/slax/sqlzma/sqlzma${MY_PV}-457.tar.bz2 \
		 mirror://sourceforge/squashfs/squashfs${MY_PV}.tar.gz \
		 ftp://ftp.slax.org/source/slax/sqlzma/lzma457.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE=""

RDEPEND="sys-libs/zlib"

S="${WORKDIR}"

src_unpack() {
	unpack sqlzma${MY_PV}-457.tar.bz2

	cd "${S}"
	unpack squashfs${MY_PV}.tar.gz

	mkdir lzma457
	cd lzma457
	unpack lzma457.tar.bz2
	cd "${S}"

	# some of the patchs in the 2k patch refer to the kernel, but as this ebuild
	# only handles the kernel module the failed patch lines can be ignored
	patch -f -p1 -d squashfs${MY_PV} < sqlzma2k-3.4.patch
	patch -p1 -d squashfs${MY_PV} < sqlzma2u-3.4.patch || die "failed patching"
	patch -p1 -d lzma457 < sqlzma1*.patch

	sed -i \
	    -e 's: -lz -lpthread: -lpthread:' \
	    -e 's: -o \$@: -lz \0:' \
		-e 's:-O2:$(CFLAGS):' \
		squashfs${MY_PV}/squashfs-tools/Makefile || die "sed failed"

	cat >> Makefile <<EOF

tools:
	\${MAKE} -C \${LzmaC} -f sqlzma.mk libunlzma.a libunlzma_r.a
	\${MAKE} -C \${LzmaAlone} -f sqlzma.mk all
	\${MAKE} -C \${SqTools} unsquashfs mksquashfs

EOF
}

src_compile() {
	emake CC="$(tc-getCC)" \
		  CXX_C="$(tc-getCC) ${CFLAGS}" \
		  CXX="$(tc-getCXX) ${CFLAGS}" tools || die
	mv squashfs${MY_PV}/squashfs-tools/unsquashfs unsquashfs-lzma \
		|| die "could not build unsquashfs"
	mv squashfs${MY_PV}/squashfs-tools/mksquashfs mksquashfs-lzma \
		|| die "could not build mksquashfs"
}

src_install() {
	dobin mksquashfs-lzma unsquashfs-lzma || die
	cd squashfs${MY_PV}
	dodoc README ACKNOWLEDGEMENTS CHANGES PERFORMANCE.README README
}