electricsheep-9999.ebuild

electricsheep-9999.ebuild (text/plain), 1.90 KB, created by David Leverton on 2009-06-28 21:09:47 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/electricsheep/electricsheep-2.6.8-r3.ebuild,v 1.1 2009/05/01 18:41:58 patrick Exp $

EAPI=1

WANT_AUTOCONF=latest
WANT_AUTOMAKE=latest

inherit eutils flag-o-matic kde-functions subversion autotools

ESVN_REPO_URI="http://electricsheep.svn.sourceforge.net/svnroot/electricsheep/trunk/client/"

DESCRIPTION="realize the collective dream of sleeping computers from all over the internet"
HOMEPAGE="http://electricsheep.org/"
SRC_URI=""

IUSE="kde" #gnome
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""

DEPEND="dev-libs/expat
	>=gnome-base/libglade-2.5.0:2.0
	media-video/ffmpeg
	sys-libs/zlib
	>=x11-libs/gtk+-2.7.0:2
	x11-libs/libX11"
RDEPEND="${DEPEND}
	app-arch/gzip
	~media-gfx/flam3-9999
	media-video/mplayer
	net-misc/curl
	x11-misc/xdg-utils
	kde? ( kde-base/kscreensaver )"
#	gnome? ( gnome-extra/gnome-screensaver )
DEPEND="${DEPEND}
	>=dev-util/pkgconfig-0.9.0
	x11-proto/xproto"

src_unpack() {
	subversion_src_unpack
	cd "${S}"
	epatch "${FILESDIR}"/${P}-xdg-utils.patch
	epatch "${FILESDIR}"/${P}-gnome.patch
	epatch "${FILESDIR}"/${P}-external-ffmpeg.patch
	epatch "${FILESDIR}"/${P}-valgrind.patch
	eautoreconf
}

src_install() {
	emake install DESTDIR="${D}" || die "make install failed"

	# install the xscreensaver config file
	insinto /usr/share/xscreensaver/config
	doins ${PN}.xml || die "${PN}.xml failed"

	if use kde; then
		set-kdedir
		insinto /usr/share/applications
		newins ${PN}.desktop{.kde,} || die "${PN}.desktop.kde failed"
		insinto "${KDEDIR}/share/applnk/System/ScreenSavers"
		newins ${PN}.desktop{.kde,} || die "${PN}.desktop.kde failed"
	fi

	#if use gnome; then
	#	insinto /usr/share/applications/screensavers
	#	doins ${PN}.desktop || die "${PN}.desktop failed"
	#	exeinto /usr/libexec/gnome-screensaver
	#	doexe ${PN}-saver || die "${PN}-saver failed"
	#fi
}