rename and parallel make fix for 3.0 release

mdadm-3.0-fixed-j1.ebuild (text/plain), 1.76 KB, created by Michael Evans on 2009-06-17 05:18:40 UTC

## fixme, copied from 2.6.9
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
#### $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/mdadm-3.0.0.ebuild,v 1.1 2009/03/20 22:50:13 robbat2 Exp $

inherit eutils flag-o-matic

DESCRIPTION="A useful tool for running RAID systems - it can be used as a replacement for the raidtools"
HOMEPAGE="http://neil.brown.name/blog/mdadm"
SRC_URI="mirror://kernel/linux/utils/raid/mdadm/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="static"

src_unpack() {
	unpack ${A}
	cd "${S}"
	use static && append-ldflags -static
}

src_compile() {
	emake \
		CROSS_COMPILE=${CHOST}- \
		CWFLAGS="-Wall" \
		CXFLAGS="${CFLAGS}" \
		-j1 \
		all mdassemble \
		|| die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	into /
	dosbin mdassemble || die
	dodoc ChangeLog INSTALL TODO README* ANNOUNCE-${PV}

	exeinto /$(get_libdir)/rcscripts/addons
	newexe "${FILESDIR}"/raid-start.sh raid-start.sh || die "addon failed"
	newexe "${FILESDIR}"/raid-stop.sh raid-stop.sh || die "addon failed"

	insinto /etc
	newins mdadm.conf-example mdadm.conf
	newinitd "${FILESDIR}"/mdadm.rc mdadm || die "installing mdadm.rc failed"
	newconfd "${FILESDIR}"/mdadm.confd mdadm || die "installing mdadm.confd failed"
	newinitd "${FILESDIR}"/mdraid.rc mdraid || die "installing mdraid.rc failed"

	insinto /etc/udev/rules.d/
	newins "${FILESDIR}"/udev-141-64-md-raid.rules 64-md-raid.rules || die
}

pkg_postinst() {
	elog "If using baselayout-2 and not relying on kernel auto-detect"
	elog "of your RAID devices, you need to add 'mdraid' to your 'boot'"
	elog "runlevel. Run the following command:"
	elog "rc-update add mdraid boot"
}