# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils multilib toolchain-funcs versionator

DESCRIPTION="Google Chrome is a browser that combines a minimal design with sophisticated technology to make the web faster, safer, and easier."
HOMEPAGE="http://www.google.com/chrome"
MY_PN="${PN%-bin}-unstable"
MY_P="${MY_PN}_${PVR}"
SRC_BASE="http://dl.google.com/linux/deb/pool/main/${MY_PN:0:1}/${MY_PN}/"
SRC_URI="amd64? ( ${SRC_BASE}${MY_P}_amd64.deb ) x86? ( ${SRC_BASE}${MY_P}_i386.deb )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86" #~amd64
IUSE=""
RESTRICT="primaryuri"

RDEPEND=">=sys-devel/gcc-4.2[-nocxx]
	|| ( media-fonts/liberation-fonts media-fonts/corefonts )
	x86? (
		dev-libs/atk
		x11-libs/cairo
		media-libs/fontconfig
		media-libs/freetype
		dev-libs/glib:2
		x11-libs/gtk+:2
		dev-libs/nspr
		dev-libs/nss
		x11-libs/pango
	)
	!x86? (
		app-emulation/emul-linux-x86-baselibs
		app-emulation/emul-linux-x86-gtklibs
		app-emulation/emul-linux-x86-soundlibs
		app-emulation/emul-linux-x86-xlibs
	)"
	#x11-misc/xdg-utils

CHROME_HOME="/opt/google/chrome"
QA_EXECSTACK="${CHROME_HOME}/chrome"

pkg_nofetch() {
	elog "Please download ${SRC_BASE}${A}"
	elog "and save to ${DISTDIR}"
}

src_install() {
	cd ${D}
	gzip -cd ${WORKDIR}/data.tar.gz | tar xvf - || die "Couldn't extract"
	rm -r etc
	dosym ../../..${CHROME_HOME}/${PN%-bin}.desktop \
		/usr/share/applications/${PN%-bin}.desktop
	if use x86; then
		mkdir -p ${D}${CHROME_HOME}/lib32
		for i in nss/lib{nss{,util},smime,ssl}3.so.1d \
		         nspr/lib{pl{ds,c},nspr}4.so.0d; do
			dosym ../../../../usr/$(get_libdir)/${i%.*} \
				${CHROME_HOME}/lib32/${i##*/}.1d
		done
	fi
}

pkg_postinst() {
	elog "This Chrome binary package is from the developer preview channel.  It is"
	elog "not guaranteed to be stable or even usable."
	elog ""
	elog "Chrome's auto-update mechanism is only available for Debian-based"
	elog "distributions, and has been disabled."
	elog ""
	elog "Please see"
	elog "    http://dev.chromium.org/for-testers/bug-reporting-guidlines-for-the-mac-linux-builds"
	elog "before filing any bugs."
	use x86 || multilib_toolchain_setup x86
	if ! version_is_at_least 4.2 "$(gcc-version)" || [[ -z $(tc-getCXX) ]]; then
		einfo ""
		ewarn "This Chrome binary package depends on C++ libraries from >=sys-devel/gcc-4.2,"
		ewarn "which do not appear to be available.  Google Chrome may not run."
		ebeep
	fi
}