# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit flag-o-matic qt3 games

DESCRIPTION="Qt3-based GUI interpreter for TADS 2 and TADS 3 text adventures"
HOMEPAGE="http://qtads.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

DEPEND="x11-libs/qt:3"
RDEPEND="${DEPEND}"

LANGUAGES="de"
for i in ${LANGUAGES}; do
	IUSE="${IUSE} linguas_${i}"
done

src_unpack() {
	unpack ${A}
	cd "${S}"
	gunzip qtads.6.gz || die "gunzip qtads.6.gz failed"
}

src_configure() {
	# Work-around for a bug when compiling with some versions of g++;
	# strict-aliasing will break the Tads 3 VM.
	append-cxxflags -fno-strict-aliasing
	eqmake3 qtads.pro \
		BIN_INSTALL="${GAMES_BINDIR}" DATA_INSTALL="${GAMES_DATADIR}"
}

src_install() {
	# Install everything except documentation and i18n.
	emake INSTALL_ROOT="${D}" \
		install_target install_charmaps \
	|| die "make install failed"
	# We install documentation manually to comply with Gentoo guidelines.
	dodoc \
		AUTHORS BUGS CREDITS INSTALL NEWS PORTABILITY README \
		SOURCE_README TIPS TODO
	# Same for i18n.
	insinto "${GAMES_DATADIR}/${PN}/i18n"
	for i in ${LANGUAGES}; do
		if has ${i} ${LINGUAS}; then
			doins "${PN}_${i}.qm" || die "doins ${PN}_${i}.qm failed"
		fi
	done
	doman qtads.6
	make_desktop_entry qtads QTads
	prepgamesdirs
}