clamtk-4.12.ebuild

clamtk-4.12.ebuild (text/plain), 1.62 KB, created by keenblade on 2009-05-13 17:27:22 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"
inherit eutils

CLAMTK_KDEVER="0.13"
DESCRIPTION="A frontend for ClamAV using Gtk2-perl."
HOMEPAGE="http://clamtk.sourceforge.net/"
SRC_URI="mirror://sourceforge/clamtk/${P}.tar.gz
	kde? ( mirror://sourceforge/clamtk/clamtk-kde-${CLAMTK_KDEVER}.tar.gz )"

LICENSE="Artistic GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

LANGS="cs da de es fr gl it ja ko nl pl pt_BR ro ru sk sl sv tr zh_CN"
IUSE="nls kde"
for i in ${LANGS}; do
	IUSE="${IUSE} linguas_${i}"
done

DEPEND=""
RDEPEND=">=dev-perl/gtk2-perl-1.140
	dev-perl/File-Find-Rule
	dev-perl/libwww-perl
	dev-perl/Net-DNS
	dev-perl/Date-Calc
	dev-perl/Config-Tiny
	dev-util/desktop-file-utils
	>=app-antivirus/clamav-0.90
	nls? ( dev-perl/Locale-gettext )
	kde? ( || ( kde-base/konqueror:3.5 kde-base/kdebase:3.5 ) )"


src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e "s:'/usr/lib':'/usr/lib/"${P}"/lib':"  clamtk \
		|| die "sed failed"
}

src_install() {
	dobin clamtk

	doicon clamtk.png
	domenu clamtk.desktop

	dodoc CHANGES DISCLAIMER README
	doman clamtk.1.gz

	dodir /usr/lib/${P}/lib/ClamTk
	insinto /usr/lib/${P}/lib/ClamTk
	doins ${S}/lib/*.pm

	if use nls ; then
		cd po/
		mv cs_CZ.mo cs.mo
		for n in *.mo ; do
			if use linguas_${n/.mo} ; then
				insinto /usr/share/locale/${n/.mo}/LC_MESSAGES
				newins ${n} clamtk.mo
			fi
		done
	fi

	if use kde ; then
		cd "${WORKDIR}"/${PN}-kde-${CLAMTK_KDEVER}
		doicon ${PN}-kde.xpm
		doman ${PN}-kde.1.gz
		docinto KDE
		dodoc CHANGES README
		insinto /usr/share/apps/konqueror/servicemenus
		doins ${PN}-kde.desktop
	fi
}