# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/moonlight/moonlight-1.0.1.ebuild,v 1.1 2009/04/09 17:31:17 loki_val Exp $

EAPI=2

inherit mono multilib nsplugins

MY_P=moon-${PV}
DESCRIPTION="Moonlight is an open source implementation of Silverlight"
HOMEPAGE="http://www.mono-project.com/Moonlight"
SRC_URI="ftp://ftp.novell.com/pub/mono/sources/moon/${MY_P}.tar.bz2"
LICENSE="LGPL-2 MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# Well, by 'firefox' here we mean appropriate xulrunner version
IUSE="alsa ffmpeg pulseaudio debug test +firefox3 firefox2"
RESTRICT="mirror"

# Needed for Moonlight-2.0 profile:
#LICENSE+="Ms-PL"
# +more
#	>=dev-dotnet/rsvg-sharp-2.24.0
#	>=dev-dotnet/gtk-sharp-2.12.7
#	>=dev-lang/mono-2.2-r3[moonlight]
#	>=dev-dotnet/dbus-sharp-0.6.1a

#Moonlight-1.0 is essentially a browser plugin written in pure C.
RDEPEND="
	>=x11-libs/gtk+-2.14
	>=dev-libs/glib-2.18
	>=dev-libs/dbus-glib-0.60
	>=x11-libs/cairo-1.8.0
	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090121 )
	firefox3? ( >=net-libs/xulrunner-1.9.0.5:1.9 )
	firefox2? ( net-libs/xulrunner:1.8 )
	x11-libs/libXrandr
	alsa? ( >=media-libs/alsa-lib-1.0.18 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )
	>=media-libs/freetype-2.3.7
	>=media-gfx/imagemagick-6.2.8
	>=media-libs/fontconfig-2.6.0
	"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.23"
S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if ! use firefox2 && ! use firefox3; then
		ewarn "You are compiling Moonlight without any firefox 'bridges'."
		ewarn "Although the plugin should still work with any browser,"
		ewarn "you may experience poor performance and other issues."
	elif ! use firefox2 && has_version www-client/opera; then
		ewarn "Please note that if you're going to use Moonlight with Opera,"
		ewarn "you should enable 'firefox2' USEflag or else you may experience"
		ewarn "serious performance issues."
	fi
}

src_prepare() {
	sed -i \
		-e "s:TEST_SUBDIR = test::"	\
		-e "s:TOOLS_SUBDIR = tools::"	\
		 Makefile.in
}

src_configure() {
	econf	--enable-shared \
		--disable-static \
	 	--with-cairo=system \
		$(use_with ffmpeg) \
		$(use_with firefox3 ff3) \
		$(use_with firefox2 ff2) \
		$(use_with alsa) \
		$(use_with pulseaudio) \
		$(use_with debug) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	inst_plugin /usr/$(get_libdir)/moon/plugin/libmoonloader.so || die "installing libmoonloader failed"
	rm -f "${D}"/usr/$(get_libdir)/moon/plugin/README
	find "${D}" -name '*.la' -exec rm -rf '{}' '+' || die "la removal failed"
}